Notes

Disk info for 312a_Koala_Micro_Illustrator.dsk:

File Name: 3d0g_312a_Koala_Micro_Illustrator/312a_Koala_Micro_Illustrator.dsk
Disk Name: DISK VOLUME #254
Physical Size (bytes): 143360
Free Space (bytes): 68352
Used Space (bytes): 75008
Physical Size (KB): 140
Free Space (KB): 66
Used Space (KB): 73
Archive Order: DOS
Disk Format: DOS 3.3
Total Sectors: 560
Free Sectors: 267
Used Sectors: 293
Tracks On Disk: 35
Sectors On Disk: 16

Disk directory for 312a_Koala_Micro_Illustrator.dsk:

3d0g_312a_Koala_Micro_Illustrator/312a_Koala_Micro_Illustrator.dsk DISK VOLUME #254
* A 003 KOALA MICRO ILLUSTRATOR
* A 008 BY STEVEN DOMPIER
* A 024 COPYRIGHT (C) 1983
* B 017 ISLAND GRAPHICS INC.
* B 055 ALL RIGHTS RESERVED
* B 033 TITLE
* B 033 HELP
* I 006 APPLESOFT
* B 050 II+
DOS 3.3 format; 68,352 bytes free; 75,008 bytes used.

Text found in 312a_Koala_Micro_Illustrator.dsk/APPLESOFT.int:

10 REM APPLESOFT
20 TEXT :PRINT
30 CALL -936
80 REM --POKE LANGUAGE CARD FINDER
90 POKE 768,0: POKE 769,173: POKE 770,0: POKE 771,224: POKE 772,72: POKE 773,173: POKE 774,129: POKE 775,192: POKE 776,104:
95 POKE 777,72: POKE 778,205: POKE 779,0: POKE 780,224: POKE 781,208: POKE 782,35: POKE 783,173: POKE 784,131: POKE 785,192:
100 POKE 786,173: POKE 787,131: POKE 788,192: POKE 789,169: POKE 790,165: POKE 791,141: POKE 792,0: POKE 793,208: POKE 794,205:
105 POKE 795,0: POKE 796,208: POKE 797,208: POKE 798,19: POKE 799,74: POKE 800,141: POKE 801,0: POKE 802,208: POKE 803,205:
110 POKE 804,0: POKE 805,208: POKE 806,208: POKE 807,10: POKE 808,173: POKE 809,129: POKE 810,192: POKE 811,173: POKE 812,129:
115 POKE 813,192: POKE 814,169: POKE 815,1: POKE 816,208: POKE 817,2: POKE 818,169: POKE 819,0: POKE 820,141: POKE 821,0:
120 POKE 822,3: POKE 823,104: POKE 824,205: POKE 825,0: POKE 826,224: POKE 827,240: POKE 828,3: POKE 829,173: POKE 830,128:
125 POKE 831,192: POKE 832,96:
160 CALL 769
170 IF PEEK (768)<>1 THEN 260
180 REM
190 REM --IF THERE, LOAD APPLESOFT
200 REM
210 REM
220 PRINT "BLOADII+,A$D000,D1"
230 REM --WRITE PROTECT THE CARD
240 A= PEEK (-16254):REM $C082
250 GOTO 310
260 REM
270 REM --NO CARD OR CAN'T RELOAD
280 REM
290 IF PEEK (768)=0 THEN 310
300 PRINT "...LANGUAGE CARD CANNOT BE RELOADED":PRINT " UNTIL THE SYSTEM IS REBOOTED..."
310 PRINT "RUNKOALA MICRO ILLUSTRATOR,D1"

Text found in 312a_Koala_Micro_Illustrator.dsk/BY STEVEN DOMPIER.bas:

0 ONERR GOTO 2190
1 REM
2 REM KOALA MICRO ILLUSTRATOR
3 REM
4 REM BY STEVEN DOMPIER
5 REM COPYRIGHT (C) 1983
6 REM ISLAND GRAPHICS INC.
7 REM ALL RIGHTS RESERVED
8 REM
9 REM :BY STEVEN DOMPIER:
10 REM
30 GOTO 100
63 POKE V +17,X: POKE V +18,Y: RETURN
64 POKE V +65,X: POKE V +66,Y: RETURN
86 CALL C +12
87 GOSUB 90: IF Z <8 THEN RETURN
88 IF Z < >18 THEN 86
89 GOTO 200
90 X = PEEK(V +74):Y = PEEK(V +75):Z = PEEK(640): IF Z = 8 THEN 200
91 RETURN
96 POKE 49232,0: POKE 49239,0: POKE 49237,0: POKE 49234,0: RETURN
100 HIMEM: 4096:D$ = CHR$(4): PRINT D$"NOMONC,I,O": SPEED= 255: NORMAL :C = 25344:V = C +37: POKE 33,40: POKE 1012,0: POKE 214,128: IF NOT PEEK(V +85) THEN TEXT : HOME : PRINT D$"BLOADTITLE,A$4000,D1": GOSUB 96
120 PRINT D$"BLOADISLAND GRAPHICS INC.,D1": IF PEEK(V +85) THEN 180
125 PRINT D$"BLOADALL RIGHTS RESERVED": CALL C +24: POKE V +45,7: VTAB 18: HTAB 2: INVERSE : PRINT " PRESS KOALAPAD BUTTON FOR MENU " CHR$(27)
128 POKE 49168,0
130 IF PEEK(49152) >127 THEN 160
132 X = PEEK(49249):Y = PEEK(49250): IF X >127 THEN IF Y <128 THEN 160
134 IF Y >127 THEN IF X <128 THEN 160
136 GOTO 130
160 POKE 49168,0: CALL C +30
180 GOSUB 96
200 X = FRE(0): CALL C +3: CALL C +6
300 CM = PEEK(6): ON CM GOTO 480,480,600,700
480 CALL C +3: GOSUB 86: GOSUB 64: GOSUB 63: POKE V +54,127: POKE V +80,0: CALL C:X1 = X:Y1 = Y:X = X +3: GOSUB 510
483 CALL C +9:X = PEEK(V +74):Y = PEEK(V +75):Z = PEEK(640): IF Z <8 THEN 495
486 IF Z < >8 AND Z < >18 THEN 483
489 GOSUB 519: GOTO 480
495 IF Z < >2 THEN 504
498 GOSUB 519: POKE V +54,0: IF CM = 1 THEN POKE V +80,1
501 GOSUB 510: GOTO 480
504 IF X < >XO OR Y < >YO THEN CALL C +18: GOSUB 510
507 GOTO 483
510 XO = X:YO = Y:X = X -X1 +X -X1:Y = (Y -Y1) *1.15:RA = SQR(X *X +Y *Y): IF RA <1 THEN RA = 1
513 POKE V +79,RA/256: POKE V +78,RA - INT(RA/256) *256
516 CALL C +18: RETURN
519 CALL C +18: POKE V +17,X1: POKE V +18,Y1: CALL C: RETURN
600 HIMEM: 39590: PRINT CHR$(4)"RUNCOPYRIGHT (C) 1983"
700 POKE 49236,0: PRINT D$"BLOADHELP,A$4000,D1": POKE 49237,0: CALL C +12: CALL C +27: GOTO 200
2190 CALL C +3: HIMEM: 4096:X = FRE(0): IF CM = 3 OR CM = 4 THEN 3000
2200 GOTO 200
3000 TEXT : HOME : INVERSE : VTAB 19: PRINT CHR$(27): HTAB 7: PRINT "PRESS SPACE BAR TO CONTINUE": VTAB 14: HTAB 6: PRINT "INSERT THE 'MICRO ILLUSTRATOR'": CALL C +21: CALL C +21: HTAB 8: PRINT "DISKETTE INTO DISK DRIVE 1": NORMAL
3010 WAIT 49152,128: POKE 49168,0: GOSUB 96: GOTO 300

Text found in 312a_Koala_Micro_Illustrator.dsk/COPYRIGHT (C) 1983.bas:

0 ONERR GOTO 2190
1 REM
2 REM KOALA MICRO ILLUSTRATOR
3 REM
4 REM BY STEVEN DOMPIER
5 REM COPYRIGHT (C) 1983
6 REM ISLAND GRAPHICS INC.
7 REM ALL RIGHTS RESERVED
8 REM
9 REM :COPYRIGHT (C) 1983:
10 REM
20 HIMEM: 39590
30 D$ = CHR$(4):C = 25344:DM = 2:N = 22:DR = 1
40 X = FRE(0): GOTO 600
50 X = FRE(0):A$ = "":B$ = "":C$ = "":E$ = "":S$ = "":T$ = "":X = FRE(0): RETURN
430 CALL C +21: CALL C +21: RETURN
440 GET A$: RETURN
450 GET B$: RETURN
460 FOR H = 1 TO 500: NEXT H: RETURN
462 ONERR GOTO 2190
464 A$ = "STORAGE": GOSUB 5710: VTAB 18: HTAB 10: PRINT "SPACE BAR) TO CONTINUE": VTAB 14: HTAB 6: INVERSE : PRINT "INSERT THE 'MICRO ILLUSTRATOR'": GOSUB 430: HTAB 8: PRINT "DISKETTE INTO DISK DRIVE 1": NORMAL : GOSUB 2340
470 GOSUB 50: ONERR GOTO 462
490 VTAB 20: PRINT : PRINT D$"RUNBY STEVEN DOMPIER,D1"
600 T9 = 0: ONERR GOTO 2190
610 GOTO 630
620 GOSUB 1770
630 GOSUB 50: CALL C +3:A$ = "STORAGE"
650 S$ = "": GOSUB 5710: GOSUB 1880: PRINT "C) ";: GOSUB 780: PRINT C$: PRINT : PRINT "U) ";: GOSUB 1970: PRINT A$: PRINT
670 PRINT "L) ";: GOSUB 810: PRINT C$: PRINT : PRINT "S) ";: GOSUB 820: PRINT C$
680 GOSUB 1940: PRINT "MENU"
720 GOSUB 730: GOTO 960
730 IF T9 THEN 750
740 FLASH : GOSUB 770: FOR I = 1 TO 850: NEXT :T9 = 1
750 GOTO 760
760 INVERSE : GOSUB 770: NORMAL : POKE 32,0: RETURN
770 VTAB 20: HTAB 6: PRINT "INSERT TARGET DISK": RETURN
780 C$ = "CATALOG DISK": RETURN
790 C$ = "FORMAT DATA DISK": RETURN
800 GOSUB 870: PRINT C$: RETURN
810 GOSUB 920: GOTO 870
820 GOSUB 930
870 C$ = C$ +" STANDARD DOS 3.3 PICTURE":E$ = "PICTR.":A = 16384:B = 8184:M = A/2: RETURN
920 C$ = "LOAD": RETURN
930 C$ = "SAVE": RETURN
960 GOSUB 2320: GOSUB 440: IF A$ = " " THEN POKE 34,0: GOTO 470
980 GOSUB 1960: IF A$ = "U" THEN 1980
990 IF A$ = "L" THEN 1190
1000 IF A$ = "S" THEN 1200
1010 IF A$ < >"C" THEN 630
1020 GOSUB 780: GOSUB 1240: GOSUB 1760: VTAB 4: HTAB 27: INVERSE : PRINT " DRIVE ";: IF DR = 1 THEN PRINT "1": GOTO 1040
1030 PRINT "2"
1040 NORMAL : POKE 44606,20: POKE 34,2: VTAB 1: PRINT : VTAB 1: PRINT D$"CATALOG,D"DR
1050 VTAB 24: HTAB 4: INVERSE : PRINT "PRESS (SPACE BAR) TO RETURN TO MENU";: NORMAL : GOSUB 2340
1060 GOTO 630
1070 GOSUB 790: GOSUB 1240: HOME : GOSUB 1760: GOSUB 1820: VTAB 6: HTAB 1
1080 HTAB 6: PRINT "A DATA DISK IS CREATED USING": HTAB 6: PRINT "STANDARD DOS 3.3 TYPE FORMAT,": HTAB 6: PRINT "ALLOWING STORAGE OF PICTURES."
1090 VTAB 12: HTAB 1: INVERSE : PRINT "CAUTION:";: NORMAL : PRINT " EXISTING DATA ON THE DISKETTE": PRINT "TO BE FORMATTED WILL BE ERASED."
1100 VTAB 16: HTAB 3: PRINT "INSERT ";: INVERSE : PRINT "BLANK";: NORMAL : PRINT " DISKETTE INTO ";: INVERSE : PRINT "DRIVE 1": NORMAL
1110 GOSUB 2340
1130 ONERR GOTO 1175
1140 VTAB 20: PRINT : PRINT D$"VERIFYKOALA MICRO ILLUSTRATOR,D1"
1145 ONERR GOTO 2190
1150 VTAB 20: HTAB 1: FLASH : GOSUB 430: PRINT "*** REMOVE THE ILLUSTRATOR DISKETTE ***": NORMAL
1160 GOSUB 2340: GOTO 1070
1175 ONERR GOTO 2190
1180 POKE 34,15: POKE 35,24: HOME : POKE 34,2: VTAB 16: HTAB 15: FLASH : PRINT "FORMATTING": NORMAL : POKE 42344,76: POKE 44723,4: POKE 46922,96: PRINT D$"INITH,D1": POKE 40147,0: GOTO 630
1190 GOSUB 810: GOTO 1210
1200 GOSUB 820
1210 GOSUB 1220: GOTO 630
1220 GOSUB 1240: GOTO 1420
1230 T = (40 - LEN(C$))/2 +1: VTAB 4: HTAB T: INVERSE : PRINT C$: NORMAL : RETURN
1240 T$ = C$: IF E$ = "" AND LEFT$(C$,1) < >"F" THEN C$ = C$ +" FILE"
1250 GOSUB 1230:C$ = T$:T$ = LEFT$(C$,1): IF T$ = "F" THEN RETURN
1260 IF DM >1 THEN 1290
1270 DR = 1: IF A$ = "C" THEN RETURN
1280 GOTO 1340
1290 GOSUB 1820: VTAB 6: HTAB 12: PRINT "SELECT DISK DRIVE": GOSUB 1360
1300 GOSUB 2330: IF A$ = " " OR ASC(A$) = 13 THEN 1340
1310 IF ASC(A$) = 27 THEN 620
1320 T = VAL(A$): IF T < >1 AND T < >2 THEN 1300
1330 DR = T
1340 POKE 35,24: HOME : VTAB 8: INVERSE : IF DR = 1 THEN HTAB 4: GOTO 1390
1350 HTAB 25: GOTO 1400
1360 VTAB 8: HTAB 1: IF DR = 1 THEN INVERSE
1370 PRINT "1) ";: GOSUB 1390: NORMAL : HTAB N: IF DR = 2 THEN INVERSE
1380 PRINT "2) ";: GOSUB 1400: NORMAL : RETURN
1390 PRINT "DISK DRIVE 1";: RETURN
1400 PRINT "DISK DRIVE 2";: RETURN
1420 C$ = LEFT$(C$,4)
1430 GOSUB 1820: VTAB 12: HTAB 6: PRINT "TYPE NAME OF PICTURE TO ";: INVERSE : PRINT C$: NORMAL
1440 A$ = E$:T = 14:H = 13: IF A$ = "" THEN H = 7
1450 IF S$ < >"" THEN T = 18
1460 VTAB T: HTAB 4: PRINT "==>";: HTAB 37: PRINT "<==";: HTAB 7: PRINT A$;
1470 VTAB T: HTAB H: GOSUB 450: IF ASC(B$) = 13 THEN 1580
1480 IF ASC(B$) < >8 THEN 1540
1490 IF LEN(A$) = 0 THEN 1560
1500 IF LEN(A$) = 1 THEN A$ = "": GOTO 1520
1510 A$ = LEFT$(A$, LEN(A$) -1)
1520 H = H -1: VTAB T: HTAB H: PRINT " "
1530 GOTO 1470
1540 IF ASC(B$) = 27 THEN 620
1550 IF LEN(A$) <30 THEN 1570
1560 CALL C +21: GOTO 1470
1570 PRINT B$;:A$ = A$ +B$:H = H +1: GOTO 1470
1580 IF LEN(A$) <1 THEN 620
1590 IF A$ = E$ THEN 620
1600 IF T$ = "R" OR T$ = "V" THEN RETURN
1610 IF T$ < >"D" THEN 1630
1620 VTAB 16: HTAB 1: INVERSE : PRINT C$":";: NORMAL : PRINT " "A$: VTAB 18: HTAB 14: FLASH : PRINT "ARE YOU SURE?": NORMAL : GOSUB 1780: IF B$ < >"Y" THEN 620
1630 GOSUB 1800: PRINT : IF C$ = "SAVE" THEN 1720
1640 IF C$ < >"LOAD" THEN 1675
1650 POKE 45362,56: PRINT : PRINT D$"VERIFY"A$",D"DR: POKE 45362,24:T = PEEK(46582): IF T < >4 AND T < >132 THEN POKE 222,13: GOTO 2190
1660 T = 46539:T = PEEK(T) + PEEK(T +1) *256:T = PEEK(T +2) + PEEK(T +3) *256: IF T >M THEN POKE 222,14: GOTO 2190
1670 IF C$ = "LOAD" AND A = 16384 THEN CALL C +30: POKE 49232,0: POKE 49239,0: POKE 49237,0
1675 PRINT : PRINT D$;: IF E$ < >"" THEN PRINT "B";
1680 PRINT C$A$;: IF E$ = "" THEN 1704
1690 PRINT ",A"A;: IF C$ = "LOAD" THEN 1704
1700 PRINT ",L"B;
1704 PRINT ",D"DR: IF C$ = "LOAD" AND A = 16384 THEN FOR I = 1 TO 2800: NEXT : TEXT
1712 GOTO 630
1720 ONERR GOTO 1740
1730 GOSUB 1830: VTAB 18: HTAB 6: INVERSE : GOSUB 430: PRINT "EXISTING FILE: OK TO OVERWRITE?": GOSUB 1780: IF B$ < >"Y" THEN 620
1740 ONERR GOTO 2190
1750 GOTO 1670
1760 POKE 35,24: HOME : VTAB 24: INVERSE : HTAB 6: PRINT "PRESS (SPACE BAR) TO CONTINUE";: NORMAL : POKE 35,23: RETURN
1770 POKE 34,2:T$ = "CANCEL": GOSUB 1810: FOR H = 1 TO 999: NEXT : RETURN
1780 NORMAL : POKE 34,21: POKE 35,24: HOME : POKE 34,2: VTAB 21: HTAB 8: PRINT "N) NO";: HTAB 30: PRINT "Y) YES": INVERSE : GOSUB 5735: NORMAL : GOSUB 2320: GOSUB 450: IF B$ < >"Y" AND B$ < >"N" AND ASC(B$) < >27 THEN 1780
1790 IF ASC(B$) = 27 THEN 620
1800 POKE 34,18:T$ = "WORKING"
1810 POKE 35,24: HOME : VTAB 24: HTAB 14: INVERSE : PRINT "-= "T$" =-";: NORMAL : POKE 34,2: VTAB 21: HTAB 1: RETURN
1820 VTAB 22: HTAB 8: INVERSE : PRINT "PRESS (ESC) KEY TO CANCEL": NORMAL : RETURN
1830 PRINT : PRINT D$"VERIFY"A$",D"DR
1840 ONERR GOTO 2190
1850 RETURN
1860 POKE 34,23
1870 GOSUB 1760: POKE 34,2: GOSUB 2340: GOTO 630
1880 POKE 34,2: POKE 35,23: HOME : POKE 35,24: VTAB 4: POKE 32,5: PRINT : RETURN
1890 C$ = "LOCK": RETURN
1900 C$ = "UNLOCK": RETURN
1910 C$ = "VERIFY": RETURN
1920 C$ = "RENAME": RETURN
1930 C$ = "DELETE": RETURN
1940 VTAB 18: PRINT "SPACE BAR) RETURN TO ";: RETURN
1950 PRINT C$" FILE": RETURN
1960 POKE 34,4: POKE 35,23: HOME : RETURN
1970 A$ = "DISK FILE UTILITIES": RETURN
1980 GOSUB 1970: INVERSE : GOSUB 5730: GOSUB 1880: PRINT "L) ";: GOSUB 1890: GOSUB 1950: PRINT : PRINT "U) ";: GOSUB 1900: GOSUB 1950: PRINT : PRINT "V) ";: GOSUB 1910: GOSUB 1950: PRINT
1990 PRINT "R) ";: GOSUB 1920: GOSUB 1950: PRINT : PRINT "D) ";: GOSUB 1930: GOSUB 1950: PRINT : PRINT "F) ";: GOSUB 790: PRINT C$: GOSUB 1940: PRINT "STORAGE MENU": GOSUB 760
2000 GOSUB 2330: IF A$ = " " THEN 630
2010 IF ASC(A$) = 27 THEN 620
2020 E$ = "":B$ = "FILE": GOSUB 1960: IF A$ = "L" THEN GOSUB 1890: GOTO 2090
2030 IF A$ = "U" THEN GOSUB 1900: GOTO 2090
2040 IF A$ = "V" THEN GOSUB 1910: GOSUB 1240: GOSUB 1430: GOSUB 1800: GOSUB 1830: VTAB 17: HTAB 7: INVERSE : PRINT "FILE OK": GOTO 1860
2050 IF A$ = "R" THEN GOSUB 1920: GOTO 2110
2060 IF A$ = "F" THEN 1070
2070 IF A$ = "D" THEN GOSUB 1930: GOTO 2090
2080 GOTO 1980
2090 GOSUB 1240: GOTO 1430
2100 HTAB 6: NORMAL : PRINT "TYPE ";: INVERSE : PRINT B$;: NORMAL : PRINT " FILE NAME:": GOTO 1440
2110 GOSUB 1240: GOSUB 1820: VTAB 12:B$ = "OLD": GOSUB 2100:S$ = A$:B$ = "NEW": VTAB 16: GOSUB 2100
2120 ONERR GOTO 2140
2130 GOSUB 1800: GOSUB 1830: GOSUB 2180: PRINT "'NEW' FILE NAME ALREADY EXISTS": GOTO 1860
2140 ONERR GOTO 2190
2150 PRINT D$"RENAME"S$","A$",D"DR
2160 GOTO 630
2170 X = FRE(0): IF PEEK(222) = 255 THEN 620
2180 POKE 32,0: POKE 34,20: POKE 35,24: HOME : VTAB 21: HTAB 1: PRINT : VTAB 21: HTAB 1: INVERSE : PRINT "-->";: NORMAL : PRINT " ";: GOTO 430
2190 CALL C +3: POKE 45362,24: POKE 40147,0: TEXT : GOSUB 2170: ON PEEK(222) GOTO 2210,2210,2210,2220,2210,2230,2210,2240,2250,2260,2270,2210,2290,2280
2210 PRINT "ERROR: "; PEEK(222)"-" PEEK(218) + PEEK(219) *256: GOTO 2300
2220 PRINT "DISKETTE IS WRITE PROTECTED": GOTO 2300
2230 PRINT "FILE NOT FOUND": GOTO 2300
2240 PRINT "I/O: CHECK DISKETTE & DRIVE DOOR": GOTO 2300
2250 PRINT "DISK FULL": GOTO 2300
2260 PRINT "FILE IS LOCKED": GOTO 2300
2270 PRINT "FILE NAME SYNTAX ERROR": GOTO 2300
2280 PRINT "FILE TOO BIG": GOTO 2300
2290 PRINT "WRONG FILE TYPE"
2300 POKE 34,21: GOTO 1870
2320 VTAB 24: HTAB 40: RETURN
2330 GOSUB 2320: GOTO 440
2340 GOSUB 2330: IF ASC(A$) = 27 THEN POP : GOTO 620
2350 IF A$ < >" " AND ASC(A$) < >13 THEN 2340
2360 RETURN
5700 POKE 33,40: HOME : INVERSE : VTAB 1: HTAB 1: PRINT " +++ KOALA MICRO ILLUSTRATOR +++ ": RETURN
5705 VTAB 24: PRINT " SPACE BAR) RETURN TO MENU ";: RETURN
5710 GOSUB 5700: GOSUB 5735
5730 GOSUB 5732: TEXT : VTAB 6: HTAB 4: RETURN
5732 T = (40 - LEN(A$))/2 -3: VTAB 2: HTAB 1: GOSUB 5750: PRINT "-= "A$" =-";: GOSUB 5740: NORMAL : VTAB 6: HTAB 4: RETURN
5735 VTAB 24: HTAB 3: PRINT "USE -> KEYBOARD <- TO SELECT COMMAND";: RETURN
5740 IF INT(T) < >T THEN T = T +1
5750 FOR H = 1 TO T: PRINT " ";: NEXT : RETURN

Text found in 312a_Koala_Micro_Illustrator.dsk/KOALA MICRO ILLUSTRATOR.bas:

1 REM
2 REM KOALA MICRO ILLUSTRATOR
3 REM
4 REM BY STEVEN DOMPIER
5 REM COPYRIGHT (C) 1983
6 REM ISLAND GRAPHICS INC.
7 REM ALL RIGHTS RESERVED
8 REM
9 REM :KOALA MICRO ILLUSTRATOR:
10 REM
20 POKE 25466,0: POKE 1012,0: POKE 214,128
30 PRINT CHR$(4)"MAXFILES1"
40 POKE 25466,0: POKE 1012,0: POKE 214,128
50 PRINT CHR$(4)"RUNBY STEVEN DOMPIER,D1"