Notes

Disk info for 196a_Pro_Byter_Beagle_Brothers.dsk:

File Name: 3d0g_196a_Pro_Byter_Beagle_Brothers/196a_Pro_Byter_Beagle_Brothers.dsk
Disk Name: /PRO.BYTER/
Physical Size (bytes): 143360
Free Space (bytes): 1536
Used Space (bytes): 141824
Physical Size (KB): 140
Free Space (KB): 1
Used Space (KB): 138
Archive Order: DOS
Disk Format: ProDOS
Total Blocks: 280
Free Blocks: 3
Used Blocks: 277
Volume Access: Destroy Read Rename Write
Block Number of Bitmap: 6
Creation Date: 05/10/1985
File Entries Per Block: 13
File Entry Length (bytes): 39
Active Files in Root Directory: 28
Minimum ProDOS Version Required: 0
Volume Created By ProDOS Version: 1
Volume Name: PRO.BYTER

Disk directory for 196a_Pro_Byter_Beagle_Brothers.dsk:

3d0g_196a_Pro_Byter_Beagle_Brothers/196a_Pro_Byter_Beagle_Brothers.dsk /PRO.BYTER/
PRO-BYTER UNK 000 05/10/1985 05/10/1985 0
COPYRIGHT 1985 UNK 000 05/10/1985 05/10/1985 0
BERT KERSEY AND UNK 000 05/10/1985 05/10/1985 0
JACK CASSIDY UNK 000 05/10/1985 05/10/1985 0
BEAGLE BROS,INC UNK 000 05/10/1985 05/10/1985 0
^ UNK 000 05/10/1985 05/10/1985 0
* PRODOS SYS 030 09/18/1984 09/18/1984 14,848 A=$2000
* BASIC.SYSTEM SYS 021 09/18/1984 09/18/1984 10,240 A=$2000
* FREEBIES DIR 001 05/10/1985 05/10/1985 512
* ASCII.CHART BAS 003 05/10/1985 05/10/1985 1,024 A=$0801
* ASCII.SWITCH BAS 003 05/10/1985 05/10/1985 739 A=$0801
* BAD.NEWS BAS 001 05/10/1985 05/10/1985 417 A=$0801
* D.CODE.DEMO BAS 020 05/10/1985 05/10/1985 9,686 A=$0801
* MACHINE.ID BAS 004 05/10/1985 05/10/1985 1,513 A=$0801
* OPCODES BAS 012 05/10/1985 05/10/1985 5,468 A=$0801
* HOME.MOVIES DIR 001 05/10/1985 05/10/1985 512
* APPLE.ALARM BAS 007 05/10/1985 05/10/1985 3,072 A=$0801
* WAGGER BAS 004 05/10/1985 05/10/1985 1,529 A=$0801
* ALARM.PIC BIN 017 05/10/1985 05/10/1985 8,192 A=$1FFF
* WAGGER.PIC BIN 017 05/10/1985 05/10/1985 8,192 A=$1FFF
^ UNK 000 05/10/1985 05/10/1985 0
* BYTEZAP.PRO BAS 029 05/30/1985 05/10/1985 14,070 A=$0801
* BZAP.BIN BIN 016 05/30/1985 05/10/1985 7,308 A=$5200
* BZAP.VAR VAR 007 05/10/1985 05/10/1985 2,986 A=$7A5B
* CALL.BASIC BAS 010 05/10/1985 05/10/1985 4,350 A=$0801
* CALL.BASIC.BIN BIN 001 05/10/1985 05/10/1985 438 A=$4000
* CATA.LOG BAS 007 05/10/1985 05/10/1985 2,872 A=$0801
* DATE.SET BAS 005 05/10/1985 05/10/1985 1,597 A=$0801
* LIST.LOCK BAS 001 05/30/1985 05/10/1985 431 A=$0801
* MEM.ZAP BIN 011 05/10/1985 05/10/1985 5,040 A=$4000
* MEM.ZAP.1000 BIN 011 05/10/1985 05/10/1985 5,040 A=$1000
* MESSAGE.DECODER BAS 003 05/30/1985 05/10/1985 1,020 A=$0801
* NOTES BAS 010 05/31/1985 05/10/1985 4,606 A=$0801
* QSORT BIN 006 05/10/1985 05/10/1985 2,349 A=$4000
* QSORT.DEMO BAS 003 05/30/1985 05/10/1985 665 A=$0801
* SCRAMBLED.BASIC BAS 003 05/30/1985 05/10/1985 787 A=$0801
* STARTUP BAS 005 05/31/1985 05/10/1985 1,838 A=$0801
* TYPE BIN 001 05/10/1985 05/10/1985 333 A=$5000
ProDOS format; 1,536 bytes free; 141,824 bytes used.

Text found in 196a_Pro_Byter_Beagle_Brothers.dsk/BEAGLE BROS,INC.txt:

Offset Hex Data Characters
======= ================================================ =================
** END **

Text found in 196a_Pro_Byter_Beagle_Brothers.dsk/BERT KERSEY AND.txt:

Offset Hex Data Characters
======= ================================================ =================
** END **

Text found in 196a_Pro_Byter_Beagle_Brothers.dsk/CALL.BASIC.bas:

0 GOTO 10
1 REM THIS SPACE FOR RENT.
2 END
10 ONERR GOTO 8000
1000 SPEED= 255: PRINT CHR$(21): TEXT : HOME : INVERSE :X = 14: PRINT : PRINT
1005 GOSUB 9995: GOSUB 9999: IF NOT ( PEEK(16384) = 173 AND PEEK(16497) = 55 AND PEEK(16819) = 89) THEN PRINT D$"BLOADCALL.BASIC.BIN,A$4000"
1006 REM DISPLAY MENU
1010 X = 10: PRINT
1015 VTAB 11: CALL CS: PRINT : HTAB X: PRINT "D - DEMONSTRATE CALL.BASIC"
1025 PRINT : HTAB X: PRINT "E - ENTER A ONE-LINER"
1030 PRINT : HTAB X: PRINT "A - ASSEMBLE"
1035 PRINT : HTAB X: PRINT "L - LEAVE THIS PROGRAM"
1050 FOR I = 0 TO 3: VTAB 12 +2 *I: HTAB X: INVERSE : PRINT A$(I);: FOR J = 0 TO 30: GOSUB 9500: NEXT : NORMAL : HTAB X: PRINT A$(I): NEXT : GOTO 1050
1999 REM DEMO
2000 HOME : INVERSE : PRINT " CALL.BASIC DEMO:": NORMAL
2018 SPEED= 234: PRINT : PRINT "THIS SIMPLE 1-LINER AVERAGES 3 NUMBERS:": PRINT : PRINT "1 PRINT "Q$"THE AVERAGE IS:"Q$";(A+B+C)/3": PRINT
2020 PRINT "AFTER ASSEMBLING THIS 1-LINER INTO A CALL.BASIC FILE ON DISK, YOU COULD USE IT LIKE THIS:"
2025 PRINT : PRINT "- BRUN AVERAGER,A16384 (OR ANY ADDRESS) - A=123: B=50: C=999 (ANY VALUES) - CALL 16384 (SAME NO.AS BRUN ADDRESS)"
2030 PRINT : PRINT "CALL.BASIC ROUTINES CAN BE LOADED AND USED FROM WITHIN PROGRAMS TOO:"
2035 PRINT : PRINT " 100 AVG=16384": PRINT " 110 PRINT CHR$(4)"Q$"BRUN AVERAGER,A"Q$"AVG": PRINT " 200 A=12345: B=23456: C=34567": PRINT " 300 CALL AVG"
2040 PRINT : PRINT "COMPLEX 1-LINERS WORK TOO.": PRINT "USE YOUR IMAGINATION!";
2055 GOSUB 10000
2060 INVERSE : PRINT " ANOTHER DEMO:": NORMAL : PRINT
2070 PRINT "YOU CAN PRINT A STRING AS MANY TIMES AS YOU WANT, THANKS TO THIS 1-LINE ROUTINE THAT IS ACTUALLY IN MEMORY NOW AT 16544:";: PRINT
2080 PRINT " 1 FOR I=1 TO X: PRINT A$;: NEXT: PRINT"
2090 PRINT "HERE'S HOW YOU PRINT A STRING 13 TIMES: A$="Q$"-*-"Q$":X=13:CALL 16544": PRINT :A$ = "-*-":X = 13: CALL 16544: PRINT
2095 PRINT : PRINT "OR WE KIND OF LIKE:": PRINT " A$="Q$" BEAGLE BROS "Q$":X=21:CALL 16544":A$ = " BEAGLE BROS ": PRINT :X = 21: CALL 16544: PRINT
2120 GOSUB 10000
2140 INVERSE : PRINT " AND ANOTHER:": NORMAL : PRINT : PRINT "HERE'S A PROGRAM THAT DRAWS A HI-RES BOX. X AND Y ARE THE COORDINATES AND L IS THE LENGTH OF EACH SIDE:"
2160 PRINT : PRINT " 1 HPLOT X,Y TO X + L,Y TO X + L ,Y + L TO X,Y + L TO X,Y"
2170 PRINT : PRINT : PRINT "HERE'S A SAMPLE APPLESOFT PROGRAM THAT CALLS THE ROUTINE ABOVE AT 16676:"
2180 LIST 2500 -2520: PRINT "IMPORTANT: ANY IF-STATEMENT MUST BE ON A SEPARATE LINE FROM THE CALL."
2188 VTAB 23: PRINT : PRINT "PRESS A KEY TO SEE IT WORK:";: GET A$: PRINT A$: HOME
2500 HGR : HCOLOR= 3:BOX = 16676:X = 10:Y = 50:L = 10
2510 CALL BOX
2520 X = X +10:Y = Y -3:L = X: IF X <130 THEN 2510
2530 HOME : VTAB 22: PRINT "TYPE "Q$"RUN"Q$" TO RESTART PROGRAM.": SPEED= 255: END
3999 REM ENTER ROUTINE
4000 HOME : PRINT : INVERSE : PRINT " TO ENTER YOUR ROUTINE:": NORMAL
4010 PRINT : PRINT "1.REPLACE LINE 1 WITH YOUR ONE-LINER.": PRINT " (AVOID DOS COMMANDS, GOTO & GOSUB.)"
4100 PRINT : PRINT "2.TEST YOUR ONE-LINER BY TYPING "Q$"RUN 1"Q$".";: HTAB 34: PRINT "-----": PRINT "3.TYPE "Q$"RUN"Q$" AND SELECT A:ASSEMBLE.";: HTAB 25: INVERSE : PRINT "A": NORMAL : HTAB 9: PRINT "---"
4110 FOR I = 1 TO 40: PRINT "-";: NEXT : PRINT "CAUTION: DON'T CALL YOUR ROUTINE FROM WITHIN A FOR-NEXT LOOP OR FROM A LINE THAT CONTAINS AN IF STATEMENT.": FOR I = 1 TO 40: PRINT "-";: NEXT
4500 PRINT : PRINT "REPLACE LINE 1 NOW:": POKE 34,17: LIST -2: TEXT : VTAB 23: END
5999 REM ASSEMBLE
6000 HOME : INVERSE : PRINT " ASSEMBLING:": NORMAL : PRINT
6120 POKE 34,2: HOME : POKE 33,33: LIST 1:V = PEEK(37) +1:L = V -2
6200 Q = 0:C = -1: FOR I = 4 TO L: VTAB I:SB = PEEK(40) + PEEK(41) *256: REM CALCULATE SCREEN BASE
6205 FOR J = SB TO SB +32:B = PEEK(J): POKE J,32: FOR R = 0 TO 20: NEXT : POKE J,B: REM SCANNING CURSOR
6210 IF J <1411 AND I = 4 THEN NEXT : REM SKIP THE LINE NUMBER
6212 IF B < >160 OR Q = 1 THEN C = C +1:M1 = PEEK(49200): POKE ST +C,B -128: REM ADD ANOTHER CHARACTER
6215 IF B = 162 THEN Q = 1 -Q: REM TOGGLE QUOTE FLAG
6220 VTAB V: HTAB 10: PRINT "DRIVER LENGTH: 108"
6240 VTAB V +1: HTAB 10: PRINT "YOUR ROUTINE : ";: IF C +1 <100 THEN PRINT " ";
6245 IF C +1 <10 THEN PRINT " ";
6250 PRINT C +1" ";
6255 VTAB V +2: HTAB 10: PRINT "------------------"
6260 VTAB V +3: HTAB 10: PRINT "TOTAL BYTES : "C +109" "
6300 NEXT : NEXT :EN = ST +C +1: POKE EN,0: NORMAL : POKE 33,40:A = 16384: CALL A
6330 POKE 34,0: VTAB V +4: PRINT : PRINT "YOUR ROUTINE IS NOW INSTALLED IN MEMORY.TO TEST IT, CALL 16384. ----------"
6335 PRINT : PRINT "TO SAVE YOUR ROUTINE ON DISK, TYPE:": PRINT " BSAVE ANYNAME........,A$16384,E"EN: PRINT " ------------------------------------"
6340 PRINT : PRINT "IF YOU MIGHT WANT TO EDIT YOUR 1-LINER LATER, SAVE THIS ENTIRE PROGRAM NOW. ------------------------";: VTAB PEEK(37) -5: END
7999 REM ERROR
8000 EL = PEEK(219) *256 + PEEK(218):ER = PEEK(222)
8010 IF ER = 6 AND EL = 6400 THEN 6410
8015 IF ER = 8 THEN PRINT BP$: PRINT " CHECK THE DRIVE AND PRESS ANY KEY": WAIT KP,128: POKE KR,0: RESUME
8020 IF ER = 6 THEN TEXT : HOME : VTAB 8: PRINT BP$: PRINT "THE FILE "Q$"CALL.BASIC.BIN"Q$" IS MISSING.": END
8030 POKE 216,0: RESUME
8999 REM GET KEYPRESS
9500 KEY = PEEK(KP): IF KEY <128 THEN RETURN
9510 NORMAL : POKE KR,0: IF KEY >224 THEN KEY = KEY -32
9515 IF KEY = 196 THEN 2000: REM DEMO
9520 IF KEY = 197 THEN 4000: REM ENTER
9525 IF KEY = 193 THEN 6000: REM ASSEMBLE
9530 IF KEY = 204 THEN VTAB 21: PRINT : PRINT "COME BACK SOON.": END
9535 PRINT BP$;: RETURN
9899 REM DEFINE VARIABLES
9995 ST = 16492:D$ = CHR$(4):Q$ = CHR$(34):BP$ = CHR$(7):KP = 49152:KR = 49168:A$(0) = "D":A$(1) = "E":A$(2) = "A":A$(3) = "L"
9997 CS = -958:CL = -868: RETURN
9998 REM TITLE SCREEN
9999 INVERSE : HTAB X: PRINT ":" SPC( 12)":": HTAB X: PRINT " CALL.BASIC ": HTAB X: PRINT ":" SPC( 12)":": NORMAL : PRINT : HTAB X -8: PRINT "BY BERT KERSEY & RANDY BRANDT": HTAB X -1: PRINT "BEAGLE BROS, INC.": PRINT : HTAB X: PRINT "(READ PAGE 38)": RETURN
10000 FLASH : VTAB 24: HTAB 37: PRINT "KEY";: NORMAL : WAIT KP,128: POKE KR,0: HOME : RETURN

Text found in 196a_Pro_Byter_Beagle_Brothers.dsk/CATA.LOG.bas:

1 GOTO 100
2 GOSUB 63999: PRINT CHR$(4)"SAVE/PRO.BYTER/CATA.LOG": END
100 ONERR GOTO 9000
110 PRINT CHR$(4)"-QSORT"
150 CLEAR
200 PSLOT = 1
250 DIM SUBDIR$(25),FILE$(125):FI = -1:COL = 39:PR = ( PEEK(800) = 123):SR = ( PEEK(801) = 123):DR = PEEK(802): IF DR <1 OR DR >2 THEN DR = PEEK(48701)
300 L$ = " ------------------- ------ --------------- --------------- ------- -------"
310 T$ = " NAME TYPE BLOCKS MODIFIED CREATED ENDFILE SUBTYPE"
400 TEXT : PRINT CHR$(21): PRINT CHR$(4)"PR#0": NORMAL : HOME : PRINT : INVERSE : PRINT ": :": PRINT " CATA.LOG ": PRINT ": :": NORMAL
450 PRINT : PRINT "THIS PROGRAM WILL DISPLAY THE FILE NAMES FROM ALL OF THE DIRECTORIES --- ON A PRODOS DISK."
500 VTAB 11: PRINT : PRINT "[P] USE PRINTER AND 80-COLUMNS?.";: POKE 50,255 -192 *(PR = 1): PRINT "YES";: NORMAL : PRINT "/";: POKE 50,255 -192 *(PR = 0): PRINT "NO ": NORMAL
525 PRINT "[S] SORT/MERGE SUBDIRECTORIES?..";: POKE 50,255 -192 *(SR = 1): PRINT "YES";: NORMAL : PRINT "/";: POKE 50,255 -192 *(SR = 0): PRINT "NO ": NORMAL
550 PRINT "[D] DRIVE NUMBER................";: POKE 50,255 -192 *(DR = 1): PRINT " 1 ";: NORMAL : PRINT "/";: POKE 50,255 -192 *(DR = 2): PRINT " 2 ": NORMAL
560 PRINT : PRINT "[B] BEGIN": PRINT "[Q] QUIT": PRINT : CALL -868: PRINT "SELECT:";: GET A$: PRINT A$: IF A$ = "Q" THEN 63000
570 IF A$ = "P" THEN PR = PR = 0: POKE 800,123 *PR: GOTO 500
575 IF A$ = "S" THEN SR = SR = 0: POKE 801,123 *SR: GOTO 500
580 IF A$ = "D" THEN DR = DR +(DR = 1) -(DR = 2): POKE 802,DR: GOTO 500
600 IF A$ < >"B" THEN 500
750 IF SR THEN 5000
800 IF PR THEN HOME : PRINT "PRESS ESC TO QUIT": PRINT " ---"
850 IF PR THEN COL = 79: PRINT CHR$(21): PRINT CHR$(4)"PR#"PSLOT
900 REM UNSORTED
2000 PRINT CHR$(4)"PREFIX,D"DR: PRINT CHR$(4)"PREFIX": INPUT PFX$: GOSUB 8000: PRINT " MAIN DIRECTORY:":LN = LN +1
2040 PRINT PFX$:LN = LN +1: PRINT CHR$(4)"OPEN"PFX$",TDIR": PRINT CHR$(4)"READ"PFX$: INPUT A$
2100 INPUT A$: IF LEN(A$) AND LEFT$(A$,3) < >"BLO" THEN PRINT LEFT$(A$,COL): GOSUB 8000
2110 IF NOT LEN(A$) THEN PRINT LEFT$(L$,COL): GOSUB 8000
2120 IF MID$ (A$,18,3) < >"DIR" THEN 2200
2140 SUB = SUB +1:A$ = MID$ (A$,2,15)
2160 IF RIGHT$(A$,1) = " " THEN A$ = LEFT$(A$, LEN(A$) -1): GOTO 2160
2180 SUBDIR$(SUB) = PFX$ +A$ +"/"
2200 IF LEFT$(A$,3) < >"BLO" THEN 2100
2220 PRINT CHR$(4)"CLOSE": IF NF _{SORTED
5000 VTAB 17: PRINT : CALL -958: VTAB 20: PRINT "READING DIRECTORY...": PRINT CHR$(4)"PREFIX,D"DR: PRINT CHR$(4)"PREFIX": INPUT PFX$:VOL$ = PFX$
5020 PRINT CHR$(4)"OPEN"PFX$",TDIR": PRINT CHR$(4)"READ"PFX$
5060 INPUT A$: IF MID$ (A$,28,1) > = "0" AND MID$ (A$,28,1) < = "9" THEN FI = FI +1:FILE$(FI) = A$: VTAB 21: PRINT : PRINT LEFT$(A$,COL)
5080 IF MID$ (A$,18,3) < >"DIR" THEN 5160
5100 SUB = SUB +1:A$ = MID$ (A$,2,15)
5120 IF RIGHT$(A$,1) = " " THEN A$ = LEFT$(A$, LEN(A$) -1): GOTO 5120
5140 SUBDIR$(SUB) = PFX$ +A$ +"/"
5160 ON PEEK( -16384) = 155 GOTO 5250: IF LEFT$(A$,3) < >"BLO" THEN 5060
5180 PRINT CHR$(4)"CLOSE": IF NF PG.BREAK
8000 IF PR THEN LN = LN +1: IF LN >55 THEN LN = 0: PRINT CHR$(12)
8020 IF PEEK( -16384) = 155 THEN POKE 222,255: GOTO 9000
8040 RETURN
8999 REM ERROR
9000 PRINT CHR$(12): PRINT CHR$(4)"PR#0": PRINT CHR$(4)"CLOSE": IF PEEK(222) = 255 THEN RUN
9010 PRINT CHR$(7);: IF PEEK(222) = 6 THEN PRINT "QSORT MISSING FROM DISK": PRINT "-----": END
9030 IF PEEK(222) = 3 THEN DR = 1: POKE 802,DR: GOTO 150
9035 IF PEEK(222) = 8 THEN PRINT "I/O ERROR": FOR I = 1 TO 999: NEXT : GOTO 150
9040 POKE 216,0: RESUME
63000 VTAB 20: PRINT : CALL -958: PRINT "TYPE " CHR$(34)"RUN" CHR$(34)" TO CONTINUE.": END
63999 RETURN}

Text found in 196a_Pro_Byter_Beagle_Brothers.dsk/COPYRIGHT 1985.txt:

Offset Hex Data Characters
======= ================================================ =================
** END **

Text found in 196a_Pro_Byter_Beagle_Brothers.dsk/DATE.SET.bas:

10 TEXT : PRINT CHR$(21): HOME : NORMAL : VTAB 8
20 PRINT "CURRENT DATE AND TIME:"
50 MX$ = "JANFEBMARAPRMAYJUNJULAUGSEPOCTNOVDEC?????????"
60 A = PEEK(49040):B = PEEK(49041):MIN = PEEK(49042):HR = PEEK(49043)
70 YR = INT(B/2):MO = INT(A/32) +8 *(B -YR *2):DA = A - INT(A/32) *32
75 IF YR >99 OR MO >12 OR MO <1 OR DA >31 OR DA <1 THEN PRINT "": GOTO 90
80 PRINT CHR$(48 *(DA <10));DA"-" MID$ (MX$,MO *3 -2,3)"-" CHR$(48 *(YR <10))YR" " CHR$(48 *(HR <10))HR":" CHR$(48 *(MIN <10))MIN
90 ON EN GOTO 510: PRINT : PRINT "NEW DATE AND TIME:"
100 VTAB 11: PRINT : CALL -958: PRINT "DD-MMM-YY HH:MM": PRINT : PRINT " WHEN FINISHED": PRINT " TO START OVER": PRINT " TO QUIT": VTAB 12: HTAB 1:HT = 1:X$ = ""
110 POKE 1403,HT -1: HTAB HT: GET A$: ON A$ = CHR$(8) GOTO 100: ON A$ = CHR$(13) GOTO 200: IF A$ = CHR$(27) THEN 510
120 ON (HT <3 OR HT >7) AND (A$ <"0" OR A$ >"9") GOTO 110: ON HT = 1 AND A$ >"3" GOTO 110: ON (HT = 11 OR HT = 14) AND A$ >"5" GOTO 110: ON (HT >3 AND HT <7) AND A$ <"A" OR A$ >"Z" GOTO 110: ON LEN(X$) >10 GOTO 110
130 IF HT = 4 THEN MO$ = A$: FOR MO = 1 TO 12: IF MO$ < > MID$ (MX$,3 *MO -2,1) THEN NEXT : GOTO 110
132 IF HT = 4 THEN IF MO$ = "F" OR MO$ = "S" OR MO$ = "O" OR MO$ = "N" OR MO$ = "D" THEN X$ = LEFT$(X$,2) + MID$ (MX$,3 *MO -2,3): PRINT MID$ (MX$,3 *MO -2,3);:HT = HT +3: GOTO 170
140 IF HT = 5 THEN MO$ = RIGHT$(X$,1) +A$: FOR MO = 1 TO 12: IF MO$ < > MID$ (MX$,3 *MO -2,2) THEN NEXT : GOTO 110
142 IF HT = 5 THEN IF MO$ = "AP" OR MO$ = "AU" OR MO$ = "JA" THEN X$ = LEFT$(X$,2) + MID$ (MX$,3 *MO -2,3): PRINT CHR$(8); MID$ (MX$,3 *MO -2,3);:HT = HT +2: GOTO 170
150 IF HT = 6 THEN MO$ = RIGHT$(X$,2) +A$: FOR MO = 1 TO 12: IF MO$ < > MID$ (MX$,3 *MO -2,3) THEN NEXT : GOTO 110
160 PRINT A$;:X$ = X$ +A$
170 ON LEFT$(X$,2) >"31" OR ( LEN(X$) = 2 AND X$ <"01") GOTO 100:HT = HT +1 +(HT = 2) +(HT = 6) +(HT = 9) +(HT = 12)
180 IF HT = 8 THEN N = 29 +(MO < >2):N$ = STR$(N): IF (MO = 2 OR MO = 4 OR MO = 6 OR MO = 9 OR MO = 11) AND LEFT$(X$,2) >N$ THEN X$ = N$ + RIGHT$(X$,3): HTAB 1: PRINT N$;
190 GOTO 110
200 DA = VAL( LEFT$(X$,2)):MO$ = MID$ (X$,3,3):YR = VAL( MID$ (X$,6,2)):HR = VAL( MID$ (X$,8,2)):MI = VAL( MID$ (X$,10,2))
250 IF LEN(X$) < >11 THEN 100
400 IF YR >99 OR MO >12 OR MO <1 OR DA >31 OR DA <1 THEN PRINT CHR$(7);: GOTO 100
500 POKE 49041,YR *2 +(MO >7): POKE 49040,32 *(MO - INT(MO/8) *8) +DA: POKE 49043,HR: POKE 49042,MI:EN = 1: VTAB 8: HTAB 1: GOTO 20
510 VTAB 13 -4 *EN: PRINT : CALL -958: PRINT : PRINT "TYPE " CHR$(34)"RUN" CHR$(34)" TO MAKE A CHANGE."

Text found in 196a_Pro_Byter_Beagle_Brothers.dsk/JACK CASSIDY.txt:

Offset Hex Data Characters
======= ================================================ =================
** END **

Text found in 196a_Pro_Byter_Beagle_Brothers.dsk/LIST.LOCK.bas:

10 POKE 48647,00: POKE 48648,03: REM SENDS PRODOS TO $0300
20 LOC = 768: REM $0300
25 CMD$ = "LIST"
27 ER = 10: REM PRODOS.ERROR#
30 READ A: IF A > = 0 THEN POKE LOC,A:LOC = LOC +1: GOTO 30: DATA 8,160,0,185,0,2,217,26,3,208,11,200,192,4,208,243,40,169,10,76,9,190,40,76,158,190,-1
35 POKE 781, LEN(CMD$): FOR I = 1 TO LEN(CMD$): POKE 793 +I, ASC( MID$ (CMD$,I,1)) +128: NEXT : POKE 786,ER
40 TEXT : PRINT CMD$".LOCK INSTALLED.": PRINT : PRINT "RUN 999 TO REPAIR.": PRINT "-------": END
999 POKE 48647,158: POKE 48648,190: TEXT : FOR I = 1 TO PEEK(781): PRINT CHR$( PEEK(793 +I));: NEXT : PRINT " O.K.": END

Text found in 196a_Pro_Byter_Beagle_Brothers.dsk/MESSAGE.DECODER.bas:

40 HEX$ = "0123456789ABCDEF": TEXT : NORMAL : PRINT CHR$(21): HOME : INVERSE :A$ = ": :": PRINT A$: PRINT " MESSAGE.DECODER ": PRINT A$: NORMAL
41 PRINT : PRINT "(SEE PAGE 69)": VTAB 8:W$ = "": PRINT "NEW MESSAGE: ";: CALL -657: FOR I = 512 TO 767: IF PEEK(I) < >141 THEN W$ = W$ + CHR$( PEEK(I) -128): NEXT
105 IF NOT LEN(W$) THEN END
107 IF LEN(W$) >80 THEN W$ = LEFT$(W$,80): VTAB 8: HTAB 14: PRINT W$;: CALL -958
110 VTAB 12: PRINT : PRINT "*B___: ";: FOR I = 1 TO LEN(W$):X$ = MID$ (W$,I,1):CO = 1: RESTORE
160 READ A$: IF A$ < >X$ AND A$ < >"DONE" THEN CO = CO +1: GOTO 160
170 IF A$ = "DONE" THEN VTAB 15: PRINT : PRINT CHR$(7);"SORRY, NO "X$"'S ALLOWED": PRINT " -": PRINT "ANY KEY:";: GET A$: RUN
180 IF CO >14 THEN N = 0: PRINT MID$ (HEX$,N +1,1);:LE = LE +1: GOSUB 800
190 N = CO -14 *(CO >14): PRINT MID$ (HEX$,N +1,1);:LE = LE +1: GOSUB 800: NEXT :BY = BY +1: PRINT "F";: IF LE = 0 THEN PRINT "0";
300 PRINT : PRINT : PRINT "("BY" BYTE" CHR$(83 *(I >0));
310 PRINT ")": VTAB 1: PRINT "ENTER THE BYTES BELOW AT ONE OF THE": PRINT "ADDRESSES LISTED ON PAGE 69.": CALL -868: PRINT : PRINT "DON'T EXCEED THE NUMBER OF BYTES": PRINT "ALLOTTED FOR THE MESSAGE BEING CHANGED.": VTAB 11: PRINT "]CALL-151 <-(TRACE OVER)"
320 VTAB 10: END
800 IF LE = 2 THEN LE = 0:BY = BY +1: PRINT " ";
810 RETURN : DATA A,C,D,E,F,I,L,M,N,O,R,T,U," "
820 DATA B,G,H,K,P,S,V,W,X,Y,/,(,),.,":",DONE
999 FOR I = 0 TO 14: FOR J = 0 TO 16 STEP 16: IF I <14 OR J >0 THEN N = 47657 +J +I: HTAB J +1: PRINT N"," PEEK(N) SPC( ( PEEK(N) <100) +( PEEK(N) <10))" [" CHR$( PEEK(N))"]";
1000 NEXT : PRINT : NEXT

Text found in 196a_Pro_Byter_Beagle_Brothers.dsk/NOTES.bas:

50 SPEED= 255: PRINT CHR$(21): TEXT : POKE 49166,0:PG = 1: ONERR GOTO 9900
70 PMAX = 8: ON PG GOTO 5000,3000,5500,6037,6000,2000,4000,1000
1000 HOME : INVERSE : PRINT " LIST.LOCK ";: INVERSE : NORMAL : PRINT " (PAGE 37)": GOSUB 8000: PRINT "NOW YOU CAN INTERCEPT ANY SPECIFIC NON-PRODOS COMMAND BY CHANGING THE STRING 'CMD$'."
1010 PRINT " THE ERROR MESSAGE MAY BE CHANGED BY ALTERING THE VALUE OF VARIABLE 'ER'. SEE YOUR PEEKS & POKES CHART: LOCATION 222, ERROR MESSAGE CODES 1-21:"
1020 PRINT : PRINT " ER=2: RANGE ERROR": PRINT " ER=3: NO DEVICE CONNECTED": PRINT " ER=4: WRITE-PROTECTED": PRINT " ER=5: END OF DATA": PRINT " ER=6: PATH NOT FOUND": PRINT : PRINT " ...ETC."
1500 GOTO 9000
2000 HOME : INVERSE : PRINT " BYTEZAP.PRO ";: NORMAL : PRINT " DUMMY FILE NAMES ": GOSUB 8000: PRINT "HERE'S HOW YOU MAKE ZERO-BLOCK CATALOG TITLES LIKE THOSE ON THE PRO-BYTER DISK:";: PRINT
2020 PRINT "- MAKE A BACK-UP COPY OF A DISK, AND DELETE A FILE FROM IT.": PRINT : PRINT "- RUN BYTEZAP.PRO AND FIND THE DELETED FILE NAME (SEE PAGE 15)."
2030 PRINT : PRINT "- CHANGE THE DELETED NAME. IF LESS THAN 15 CHARACTERS, END IT WITH SPACES."
2040 PRINT : PRINT "- REFER TO PAGES 30-31 IN YOUR MANUAL, AND CHANGE BYTE [C]-[D] TO 1F. -- - CHANGE BYTES [F],[G],[H] & [I] TO 00. WRITE CHANGES TO DISK. -- "
2050 PRINT : PRINT "- ADD $01 TO BYTES [S] BY THE DIRECTORY NAME. (EXAMPLE: 0900 BECOMES 0A00.) WRITE THE CHANGE TO DISK."
2060 GOTO 9000
3000 HOME : INVERSE : PRINT " PRODOS PROBLEMS ": GOSUB 8000
3010 PRINT : PRINT "]RUN PROGRAM": PRINT : PRINT "PATH NOT FOUND": PRINT : PRINT : PRINT "]CATALOG": PRINT : PRINT "PATH NOT FOUND": PRINT : PRINT
3020 PRINT "IF YOU'RE HAVING PROBLEMS, READ PAGES 4, 53 AND 54 IN YOUR PRO-BYTER MANUAL.": GOTO 9000
4000 HOME : INVERSE : PRINT " QSORT ";: NORMAL : PRINT " (PAGE 42)": GOSUB 8000
4010 PRINT "QSORT ALWAYS INCLUDES THE FIRST ARRAY ELEMENT (#0) AS PART OF ITS SORTING PROCEDURE. DON'T FORGET TO LOOK AT THE ZERO-TH (FIRST) ITEM AFTER SORTING."
4020 RESTORE : PRINT : PRINT "-->";: FOR I = 0 TO 8: READ A$: HTAB 4: POKE 50,63 +192 *(I >0): PRINT "A$("I") = "A$: NEXT
4030 DATA MR.CHIPS,MR.ED,MR.GOODWRENCH,MR.MAGOO,MR.ROGERS,MR.T,MR.OCTOBER,MR.WIZARD,MR.WONDERFUL
4090 TEXT : GOTO 9000
5000 POKE 1063,160: POKE 1191,160: POKE 1319,160: POKE 1447,160: INVERSE :A$ = ": :"
5002 FOR I = 2 TO 15: VTAB 2: HTAB 30 -I: PRINT " PRO-BYTER ": PRINT : HTAB 30 -I: PRINT A$: VTAB 1: HTAB I: PRINT A$: PRINT : HTAB I: PRINT " NOTES ": FOR J = 1023 TO 1407 STEP 128: POKE J +I -1,160: POKE J +41 -I,160: NEXT : NEXT : NORMAL : VTAB 4: HTAB 41 - LEN(V$): PRINT V$;
5010 CALL -958: FOR I = 1 TO 333: NEXT : PRINT : PRINT " THIS PROGRAM IS AN UPDATE TO YOUR PRO-BYTER INSTRUCTION MANUAL."
5020 PRINT : PRINT " [ANY KEY] ADVANCES TO NEXT PAGE [LEFT-ARROW] GOES BACK A PAGE [ESC] LETS YOU QUIT": PRINT
5030 PRINT : INVERSE : PRINT " NOTICE:": NORMAL : PRINT : PRINT "IF YOU DON'T HAVE NAME...............A PRO-BYTER MANUAL, CLIP THIS COUPON---> ADDRESS............";
5040 PRINT "AND MAIL IT ALONG WITH $34.95 (+1.50) CITY...............TO BEAGLE BROS. STATE....ZIP.......WE SHIP SAME DAY.": PRINT "NEW DISK INCLUDED.";
5050 FOR I = 24 TO 15 STEP -1: VTAB I: HTAB 20: INVERSE : PRINT "^"; CHR$(8);: NORMAL : FOR J = 1 TO 9: NEXT : PRINT "!";: NEXT : POKE 1251,190: VTAB 14: HTAB 20: PRINT "+";: FOR I = 21 TO 40: HTAB I: INVERSE : PRINT "="; CHR$(8);: NORMAL : FOR J = 1 TO 9: NEXT : PRINT "-";: NEXT
5090 GOTO 9000
5500 HOME : INVERSE : VTAB 5: PRINT " CONTROL-S ": VTAB 1: PRINT " BYTEZAP.PRO ";: NORMAL : PRINT " (PAGES 5-35)": GOSUB 8000
5510 PRINT "NEW COMMAND:": PRINT "-----------"
5520 HTAB 13: PRINT "NOW LETS YOU SWITCH TO ANOTHER DISK DRIVE SLOT."
5530 PRINT : PRINT "THIS FEATURE IS USELESS, UNLESS YOU HAVEDRIVES CONNECTED TO DIFFERENT SLOTS. (HARD DISK USERS: SEE NEXT PAGE.)"
5600 PRINT : PRINT "IF YOU HAVE AN APPLE IIC OR 128K IIE, YOU CAN SELECT SLOT 3 AND LOOK AT PRODOS'S BUILT-IN RAM DISK, WHICH IS THESAME AS SLOT 3, DRIVE 2.": HTAB 14: PRINT "- -"
5900 GOTO 9000
6000 HOME : INVERSE : PRINT " BYTEZAP.PRO ";: NORMAL : PRINT " MORE...": GOSUB 8000
6010 PRINT "- A MINOR CHANGE: IF YOU HAVE CHANGED ANY BYTES THAT HAVEN'T BEEN WRITTEN TO THE DISK, ATTEMPTING TO MOVE THE CURSOR OFF THE SCREEN WILL NOT SWITCH TO THE NEXT BLOCK-HALF OR SECTOR."
6020 PRINT : PRINT "- YOU CAN WRITE A TRACK TO ANY DISK (NOT JUST THE ONE YOU HAVE READ FROM) BY REMOVING THE CHECKSUM STATEMENT (WITH VARIABLE 'CS') NEAR LINE 4000."
6025 PRINT : PRINT "- YOU CAN'T EASILY UNDELETE A PRODOS FILE LARGER THAN 1 BLOCK, BECAUSE THE 'DELETE' COMMAND ZAPS A FILE'S INDEX BLOCK (PG.33) FOR NO APPARENT REASON."
6028 GOTO 9000
6037 HOME : INVERSE : PRINT " BYTEZAP.PRO ";: NORMAL : PRINT " HARD DISK NOTES": GOSUB 8000
6039 PRINT "BYTEZAP.PRO WAS DESIGNED TO READ FLOPPY DISKS. IT MIGHT WORK WITH YOUR HARD DISKAND IT MIGHT NOT. DIFFERENT BRANDS VARY.";
6040 PRINT : PRINT "THE DISK MAP WILL ONLY READ THE FIRST 279 BLOCKS ON YOUR HARD DISK. DOS 3.3 DIRECTORIES AND FILES MIGHT NOT BE READABLE AT ALL."
6044 PRINT : PRINT "SEE PAGE 77 IN YOUR MANUAL FOR PROGRAM CHANGES THAT CAN BE TRIED TO GET YOUR HARD DISK TO WORK."
6500 GOTO 9000
8000 NORMAL : FOR I = 1 TO 40: PRINT "-";: NEXT : RETURN
9000 POKE -16368,0: POKE 2037,75: POKE 2038,69: POKE 2039,89
9002 K = PEEK( -16384): ON K <128 GOTO 9002: POKE -16368,0:K = K -128: IF K = 27 THEN VTAB 23: PRINT : CALL -868: VTAB 23: PRINT CHR$(4)"-/PRO.BYTER/STARTUP"
9010 IF K = 8 OR K = 10 THEN PG = PG -1: IF PG <1 THEN PG = PMAX
9020 IF K < >8 THEN PG = PG +1: IF PG >PMAX THEN PG = 1
9030 GOTO 70
9900 IF PEEK(222) = 6 THEN END
9910 POKE 216,0: RESUME

Text found in 196a_Pro_Byter_Beagle_Brothers.dsk/PRO-BYTER.txt:

Offset Hex Data Characters
======= ================================================ =================
** END **

Text found in 196a_Pro_Byter_Beagle_Brothers.dsk/QSORT.DEMO.bas:

100 TEXT : PRINT CHR$(21): HOME : NORMAL : PRINT : PRINT : PRINT "SOME RANDOM WORDS...": PRINT : PRINT CHR$(4)"-QSORT"
150 N = 18
200 VTAB 1: HTAB 1
220 DIM A$(N -1)
250 FOR I = 0 TO N -1
260 RESTORE : FOR J = 1 TO INT( RND(1) *42) +1: READ A$(I): NEXT
265 IF I >0 THEN FOR K = 0 TO I -1: IF A$(I) < >A$(K) THEN NEXT : PRINT A$(I)" "; CHR$(1 +12 *( PEEK(36) >30));: CALL -868: GOTO 270
267 IF I >0 THEN 260
270 NEXT I: IF PEEK(36) THEN PRINT CHR$(8)"!"
300 PRINT : PRINT "SORTING STARTS WHEN YOU PRESS A KEY:";: GET A$: PRINT A$;: VTAB 5: HTAB 1: CALL -958
400 CALL 950,A$(0)
450 FOR I = 0 TO N -1: PRINT SPC( (I +1) <10)I +1". "A$(I): NEXT
460 VTAB 23: PRINT : PRINT "]RUN TO TRY AGAIN.";: VTAB 23: END
510 DATA OH,SOMEWHERE,IN,THIS,FAVORED,LAND,THE,SUN,IS,SHINING,BRIGHT,THE,BAND,IS,PLAYING,SOMEWHERE,AND,SOMEWHERE,HEARTS,ARE,LIGHT,AND,SOMEWHERE,MEN,ARE,LAUGHING,AND,SOMEWHERE,CHILDREN,SHOUT,BUT,THERE,IS,NO,JOY,IN,MUDVILLE,MIGHTY,CASEY,HAS
520 DATA STRUCK,OUT

Text found in 196a_Pro_Byter_Beagle_Brothers.dsk/SCRAMBLED.BASIC.bas:

90 PRINT CHR$(21): GOTO 300
100 CLEAR : ON X = 0 TO 39: SPEED= X: XDRAW 0,39 AT X: GOSUB 0,39 AT X: RESUME X
200 VTAB 21: HTAB 1: CALL -958: PRINT " THIS PATTERN WAS CREATED BY LINE 100, USING SCRAMBLED COMMANDS (SEE PAGE 39). YOU CAN RUN 999 TO UNSCRAMBLE THEM. -------";: VTAB 23: END
300 REM SCRAMBLE.BASIC
310 POKE 47190,136: REM "MAKES 'CLEAR' WORK LIKE 'GR'
320 POKE 47181,129: REM "MAKES 'ON' WORK LIKE 'FOR'
330 POKE 47170,160: REM "MAKES 'SPEED=' WORK LIKE 'COLOR='
340 POKE 47150,142: REM "MAKES 'XDRAW' WORK LIKE 'HLIN'
350 POKE 47177,143: REM "MAKES 'GOSUB' WORK LIKE 'VLIN'
360 POKE 47167,130: REM "MAKES 'RESUME' WORK LIKE 'NEXT'
370 GOTO 100: REM THESE POKES HAVE NO EFFECT ON COMMANDS TYPED DIRECTLY FROM THE KEYBOARD.
998 REM UNSCRAMBLE.BASIC
999 POKE 47190,189: POKE 47181,180: POKE 47170,169: POKE 47150,149: POKE 47177,176: POKE 47167,166
1000 GR : FOR X = 0 TO 39: COLOR= X: HLIN 0,39 AT X: VLIN 0,39 AT X: NEXT X: HOME : PRINT : PRINT "(SAME PATTERN WITH PROPER COMMANDS)": END

Text found in 196a_Pro_Byter_Beagle_Brothers.dsk/STARTUP.bas:

1 GOTO 100: REM PRO-BYTERCOPYRIGHT (C) 1985BERT KERSEY AND JACK CASSIDYBEAGLE BROS, INC.3990 OLD TOWN AVENUESAN DIEGO, CALIFORNIA 92110
2 PRINT CHR$(4)"SAVE/PRO.BYTER/STARTUP": END
100 V$ = "29-MAY-85"
105 SPEED= 255: POKE 49166,0: ONERR GOTO 10000
110 PRINT CHR$(21): NORMAL : HOME :D$ = CHR$(4): PRINT D$"PREFIX/PRO.BYTER":PFX$ = "/PRO.BYTER/"
200 INVERSE : VTAB 1: HTAB 15: PRINT ":" SPC( 11)":": HTAB 15: PRINT " PRO-BYTER ": HTAB 15: PRINT ":" SPC( 11)":": NORMAL : PRINT : HTAB 12: PRINT "COPYRIGHT (C) 1985": HTAB 8: PRINT "BERT KERSEY & JACK CASSIDY": HTAB 13: PRINT "BEAGLE BROS, INC.": PRINT : FOR I = 1 TO 999: NEXT
250 FOR I = 1 TO 39 - LEN(V$): VTAB 9: HTAB I: PRINT " "V$: NEXT : VTAB 9
300 INVERSE : PRINT " RUN A PROGRAM:": NORMAL : HTAB 36: PRINT : PRINT " [B] BYTEZAP.PRO . . . . . . .PAGE 5 [C] CATA.LOG . . . . . . . . . . .36 [D] DATE.SET. . . . . . . . . . . 37 [Z] MEM.ZAP. . . . . . . . . . . .44"
350 PRINT " [N] NOTES (MANUAL UPDATE) . . . . .4 [Q] QUIT & RUN ANOTHER PROGRAM . . 4"
400 PRINT : INVERSE : PRINT " SEE A DIRECTORY:": PRINT : NORMAL : PRINT " [M] MAIN DIRECTORY . . . . . .PAGE 4 [F] FREEBIES SUBDIRECTORY . . . . .4 [H] HOME.MOVIES SUBDIRECTORY . . . 4": TEXT
500 VTAB 24: HTAB 1: PRINT " PRESS B,C,D,Z,N,Q,M,F OR H: " CHR$(8);: GET A$: PRINT A$;: ON A$ = "Q" OR A$ = CHR$(27) GOTO 6010: ON A$ = "M" GOTO 7000: ON A$ = "F" GOTO 8000: ON A$ = "H" GOTO 9000: ON A$ < >"B" AND A$ < >"C" AND A$ < >"D" AND A$ < >"Z" AND A$ < >"N" GOTO 500
600 VTAB 9: IF A$ < >"N" THEN HOME : PRINT "TO RETURN TO THE MENU, TYPE " CHR$(34)"-STARTUP" CHR$(34)"."
700 ON A$ = "B" GOTO 1000: ON A$ = "C" GOTO 2000: ON A$ = "D" GOTO 3000: ON A$ = "Z" GOTO 4000: ON A$ = "N" GOTO 5000: END
1000 PRINT D$"-BYTEZAP.PRO"
2000 PRINT D$"-CATA.LOG"
3000 PRINT D$"-DATE.SET"
4000 PRINT D$"-MEM.ZAP"
5000 PRINT D$"-NOTES"
6000 VTAB 20: PRINT : CALL -958: PRINT CHR$(4)"PREFIX": INPUT PFX$: PRINT "THE CURRENT PREFIX IS:": PRINT PFX$;: END
6010 VTAB 22: PRINT : CALL -958: END
7000 ONERR GOTO 9050
7010 HOME : PRINT D$"CAT": GOTO 9050
8000 ONERR GOTO 9050
8010 HOME : PRINT D$"PREFIX"PFX$"FREEBIES": PRINT D$"CAT": GOTO 9020
9000 ONERR GOTO 9050
9010 HOME : PRINT D$"PREFIX"PFX$"HOME.MOVIES": PRINT D$"CAT"
9020 HTAB 18: PRINT "^^^": SPEED= 195: FOR I = 31 TO 1 STEP -1: HTAB I: PRINT MID$ ("(YOU CAN RUN ANY BAS PROGRAM.)",I,1);: NEXT : SPEED= 255: PRINT : HTAB 18: PRINT "---": VTAB 22
9050 INVERSE : PRINT " SELECT:";:V = PEEK(37) +1:H = PEEK(36) +2: NORMAL : PRINT " [M] MAIN MENU": HTAB 13: PRINT "[Q] QUIT NOW";: IF V = 24 THEN V = 23
9060 VTAB V: HTAB H: PRINT " " CHR$(8);: GET A$: ON A$ = "M" GOTO 100: ON A$ < >"Q" AND A$ < > CHR$(27) GOTO 9060
9070 GOTO 6000
10000 POKE 216,0: RESUME

Text found in 196a_Pro_Byter_Beagle_Brothers.dsk/TYPE.txt:

Offset Hex Data Characters
======= ================================================ =================
$000000 20 58 FC 20 8E FD A2 00 BD 52 50 C9 E1 90 07 AC X| .}". =RPIa..,
$000010 98 BF 30 02 29 DF 20 ED FD E8 E0 4F D0 EA AD 07 .?0.)_ m }h`OPj-.
$000020 BE 8D A3 50 AD 08 BE 8D A4 50 A9 16 8D 07 BE A9 >.#P-.>. $P)...>)
$000030 B5 8D 08 BE A9 12 85 42 A9 B5 85 43 A9 A1 85 3C 5..>)..B )5.C)!.<
$000040 A9 50 85 3D A9 4D 85 3E A9 51 85 3F A0 00 20 2C )P.=)M.> )Q.? . ,
$000050 FE 60 D4 D9 D0 C5 A0 C3 EF ED ED E1 EE E4 8D 8A ~`TYPE C ommand..
$000060 C3 EF F0 F9 F2 E9 E7 E8 F4 A0 B1 B9 B8 B5 A0 E2 Copyrigh t 1985 b
$000070 F9 A0 D2 E1 EE E4 F9 A0 C2 F2 E1 EE E4 F4 8D C2 y Randy Brandt.B
$000080 E5 E1 E7 EC E5 A0 C2 F2 EF F3 A0 CD E9 E3 F2 EF eagle Br os Micro
$000090 A0 D3 EF E6 F4 F7 E1 F2 E5 AC A0 C9 EE E3 AE 8A Softwar e, Inc..
$0000A0 8D 38 4C 00 00 AD 6C BE 85 08 AD 6D BE 85 09 A0 .8L..-l> ..-m>..
$0000B0 01 B1 08 D9 B9 B5 D0 E9 C8 C0 05 90 F4 A9 4E 8D .1.Y95Pi H@..t)N.
$0000C0 50 BE A9 B5 8D 51 BE A2 03 8E 52 BE A9 01 8D 54 P>)5.Q>" ..R>)..T
$0000D0 BE A9 04 8D 55 BE A9 00 8D 53 BE 18 60 20 42 FC >)..U>). .S>.` B|
$0000E0 20 8E FD A2 00 8E CE BE A4 74 8C CF BE A9 C8 20 .}"..N> $t.O>)H
$0000F0 70 BE 90 03 4C 09 BE AE D0 BE 8E D6 BE 8E DE BE p>..L.>. P>.V>.^>
$000100 A2 00 8E D7 BE 8E D9 BE E8 8E DA BE E8 8E D8 BE "..W>.Y> h.Z>h.X>
$000110 A9 CA 20 70 BE 90 0C C9 05 D0 D9 20 8E FD A9 CC )J p>..I .PY .})L
$000120 4C 70 BE A0 00 B9 00 02 09 80 20 ED FD AD 00 C0 Lp> .9.. .. m}-.@
$000130 10 0F 8D 10 C0 AD 00 C0 10 FB 8D 10 C0 C9 9B F0 ....@-.@ .{..@I.p
$000140 DA C8 CC DB BE D0 DE F0 B7 54 59 50 45 .. .. .. ZHL[>P^p 7TYPE
** END **

Text found in 196a_Pro_Byter_Beagle_Brothers.dsk/^.txt:

Offset Hex Data Characters
======= ================================================ =================
** END **