Notes

Disk info for 007_Hayes_Micromodem_II_For_Apple_II_Computers.dsk:

File Name: 007_Hayes_Micromodem_II_For_Apple_II_Computers/007_Hayes_Micromodem_II_For_Apple_II_Computers.dsk
Disk Name: DISK VOLUME #254
Physical Size (bytes): 143360
Free Space (bytes): 106496
Used Space (bytes): 36864
Physical Size (KB): 140
Free Space (KB): 104
Used Space (KB): 36
Archive Order: DOS
Disk Format: DOS 3.3
Total Sectors: 560
Free Sectors: 416
Used Sectors: 144
Tracks On Disk: 35
Sectors On Disk: 16

Disk directory for 007_Hayes_Micromodem_II_For_Apple_II_Computers.dsk:

007_Hayes_Micromodem_II_For_Apple_II_Computers/007_Hayes_Micromodem_II_For_Apple_II_Computers.dsk DISK VOLUME #254
* A 005 HAYES MENU
* A 010 SELFTEST II
* A 010 STORE & FORWARD
* A 004 PICKUP
* A 007 AUTO DIAL
* I 007 DUMBO
* A 006 TRANSFER
* A 006 BASIC EXTRACTOR
* A 006 ALARM
* A 008 DIAL A HUMAN
* A 005 ANSWER ON NTH RING MODIFIED
* A 009 SOURCEON
* A 013 DJ CONVERTER
* A 016 MICROMODEM FLAGS
DOS 3.3 format; 106,496 bytes free; 36,864 bytes used.

Text found in 007_Hayes_Micromodem_II_For_Apple_II_Computers.dsk/ANSWER ON NTH RING MODIFIED.bas:

10 D$ = CHR$(4)
20 HOME
30 PRINT D$"IN#0"
40 PRINT D$"PR#0"
50 PRINT : PRINT : PRINT "THIS PROGRAM WILL WAIT FOR THE PHONE"
60 PRINT "TO RING A SET NUMBER OF RINGS BEFORE"
70 PRINT "ANSWERING AND SENDING THE ANSWER CARRIER"
80 PRINT "CONTINUE? N" CHR$(8);
90 GET AN$: PRINT AN$: IF AN$ < >"Y" THEN 60000
100 HOME : ONERR GOTO 60000
110 MSLOT = 3
120 STT = -16251 +16 *MSLOT
130 R = 0:N = 3
140 PRINT "WAITING FOR RING # ";N: CALL -958
150 FOR W = 1 TO 1300
160 IF PEEK(STT) <128 THEN 180
170 NEXT : HOME : GOTO 130
180 R = R +1
190 VTAB 8: PRINT "RING # "R
200 IF PEEK(STT) <128 THEN 200
210 IF R > = N THEN 230
220 GOTO 150
230 VTAB 10: PRINT "WAITING FOR CARRIER"
250 PRINT D$;"PR#";MSLOT
260 PRINT
270 POKE 1656 +MSLOT,128 +8 +2 +1
280 POKE 2040 +MSLOT,21
290 POKE -16250 +16 *MSLOT,21
300 PRINT
310 FOR LP = 1 TO 1000
320 IF PEEK( -16250 +16 *MSLOT) = 2 THEN 360
330 X = PEEK( -16249 +16 *MSLOT)
340 NEXT LP
350 PRINT CHR$(26): GOTO 100
360 PRINT D$;"PR#"MSLOT
370 PRINT D$;"IN#";MSLOT
380 PRINT "CONNECTION ESTABLISHED"
390 POKE 1912 +MSLOT,16 +2
400 END
60000 PRINT : PRINT D$"PR#"MS: PRINT CHR$(26): PRINT D$"PR#0"
60010 PRINT : PRINT " <<< RETURNNING TO MENU >>>"
60100 PRINT CHR$(4)"RUN HAYES MENU"
63998 REM LAST UPDATED 12/80,
63999 REM HAYES MICROCOMPUTER PRODUCTS,INC.

Text found in 007_Hayes_Micromodem_II_For_Apple_II_Computers.dsk/AUTO DIAL.bas:

1 REM AUTO DIAL PROGRAM
2 REM CHOOSE A NUMBER FROM A
3 REM MENU AND IT WILL DIAL
4 REM THE NUMBER FOR YOU AND
5 REM PUT YOU IN TERMINAL MODE
6 HOME
10 Q$ = CHR$(17):D$ = CHR$(4)
12 SLOT = 3
15 PRINT D$;"NOMON I,O,C"
20 READ NC
30 DIM PN$(NC,2)
35 PRINT "CBBS'S & OTHER SYSTEMS": PRINT "------ - ----- -------": PRINT
36 PRINT -1; TAB( 6);"END"
37 PRINT " "0; TAB( 6);"DIAL YOUR OWN"
40 FOR I = 1 TO NC
50 READ PN$(I,1),PN$(I,2)
52 IF I <10 THEN PRINT " ";
55 PRINT I; TAB( 6);PN$(I,1); TAB( 24);PN$(I,2)
60 NEXT
70 PRINT : INPUT "YOUR CHOICE?";CH
80 IF CH <0 THEN 60000
90 IF CH >NC THEN 70
100 IF CH = 0 THEN PRINT : INPUT "ENTER A NUMBER:";PN$(CH,2)
110 PRINT D$;"PR#"SLOT
115 PRINT Q$;" ";PN$(CH,2)
116 IF PEEK(1656 +SLOT) <128 THEN PRINT D$;"PR#0": PRINT "NO ANSWER OR BUSY!": CALL -198: POKE -16368,0: PRINT : GOTO 150
118 TEXT : HOME
120 PRINT D$;"PR#0"
130 PRINT D$;"IN#"SLOT
140 POKE 1912 +SLOT,128 +8 +2: INPUT I$
150 PRINT D$;"IN#0": INPUT "ANOTHER CALL?";A$: IF LEFT$(A$,1) = "Y" THEN RUN
160 GOTO 60000
200 DATA 12
215 DATA ATLANTA,1-(404) 394-4220
220 DATA BOSTON,1-(617) 354-4682
230 DATA CHICAGO,1-(312) 255-6489
240 DATA NEWJERSY,1-(609) 983-5970
250 DATA DALLAS,1-(214) 634-2668
260 DATA LOS ANGELES,1-(213) 799-1632
265 DATA SAN FERNANDO,1-(213) 340-0135
266 DATA TENNESSE,1-(901) 276-8196
267 DATA WASHINGTON,1-(703) 281-2125
270 DATA SAN DIEGO,1-(714) 526-3687
280 DATA SAN DIEGO ABBS,1-(714) 582-9557
285 DATA HOUSTON TX,1-(713) 693-3462
60000 VTAB 24: PRINT " <<< RETURNNING TO MENU >>>"
60010 PRINT CHR$(4)"RUN HAYES MENU"
63998 REM LAST UPDATED 11/80
63999 REM HAYES MICROCOMPUTER PRODUCTS, INC.

Text found in 007_Hayes_Micromodem_II_For_Apple_II_Computers.dsk/BASIC EXTRACTOR.bas:

5 REM BASIC PROGRAM EXTRACTOR
8 ONERR GOTO 9000
9 HOME
10 D$ = CHR$(4):CR$ = CHR$(13)
20 MSLOT = 3
30 GOSUB 400: PRINT : GOSUB 200
50 GOTO 1000
100 PRINT D$;"IN#0": RETURN
200 PRINT D$;"PR#0": RETURN
300 PRINT D$;"IN#";MSLOT: RETURN
400 PRINT D$;"PR#";MSLOT: RETURN
1000 ML = 10
1100 DIM I$(ML *10)
1200 PRINT D$;"NOMONI,O,C"
1400 OK$ = "OK"
1500 GOSUB 100: GOSUB 200
1550 IF PEEK(1656 +MSLOT) <127 THEN PRINT : PRINT "*** NO CONNECTION WITH COMPUTER ***": GOTO 3900
1600 INPUT "LOW LINE NUMBER? ";LL
1700 INPUT "HIGH LINE NUMBER? ";HL
1800 LI = 10
1900 INPUT "FILE NAME? ";F$
2000 PRINT D$;"OPEN ";F$
2100 X = FRE(0)
2200 L = 1
2250 INVERSE
2300 GOSUB 400: PRINT "LIST ";LL;"-"; INT(LL +(ML -1) *LI)
2350 NORMAL
2400 GOSUB 200: GOSUB 300
2402 GET A$: IF A$ < >CR$ THEN 2402
2410 I$(L) = ""
2425 GET A$
2450 IF A$ = CR$ THEN 2575
2475 PRINT A$;
2500 I$(L) = I$(L) +A$
2510 GOTO 2425
2575 PRINT
2600 IF I$(L) = OK$ THEN 2900
2700 L = L +1
2800 GOTO 2410
2900 GOSUB 100
3000 PRINT D$;"WRITE ";F$
3100 FOR I = 1 TO L -1
3200 PRINT I$(I)
3300 NEXT I
3400 PRINT D$
3500 LL = LL +(ML -1) *LI +1
3600 IF LL "Y" THEN 1500
9500 GOSUB 400: PRINT CHR$(26): GOSUB 200
9600 GOSUB 100
9700 PRINT : PRINT " <<< RETURNNING TO MENU >>>"
9800 PRINT D$"RUN HAYES MENU"
63998 REM LAST UPDATED 11/80
63999 REM HAYES MICROCOMPUTER PRODUCTS, INC.

Text found in 007_Hayes_Micromodem_II_For_Apple_II_Computers.dsk/DIAL A HUMAN.bas:

5 REM PROGRAM: DIAL A HUMAN
10 TEXT : HOME
20 READ NC
30 DIM DD$(25),D(25),PN$(NC,2)
40 D$ = CHR$(4):Z$ = CHR$(26)
50 FOR I = 1 TO NC
60 READ PN$(I,1),PN$(I,2)
70 NEXT
80 SLOT = 3:PFX$ = ""
90 KBD = -16384:CLKBD = -16368:MM2 = -16251 +16 *SLOT:OH = 136:O = 0
100 POKE 34,5: VTAB 1
105 ONERR GOTO 60000
110 PRINT " REPETITIVE DIALING PROGRAM": PRINT " FOR DIRECTORY > FOR REDIAL";
112 PRINT " TO PAUSE LISTING": PRINT " TO STOP LISTING "
115 FOR I = 1 TO 40: PRINT "=";: NEXT
120 PRINT : INPUT "NUMBER TO DIAL #";T$: IF T$ < >"/" THEN 150
130 IF C = 0 THEN HOME : GOTO 120
140 GOTO 390
150 IF T$ = "END" THEN GOTO 60000
160 IF T$ = "" THEN PRINT : PRINT "TO GET OUT TYPE 'END'": CALL -198: FOR H = 1 TO 1000: NEXT : HOME : GOTO 120
170 D2 = 0
180 IF ASC(T$) = 48 THEN 380
190 IF VAL(T$) = 0 AND LEFT$(T$,1) < >"?" THEN 310
200 IF T$ = "?" THEN 220
210 GOTO 380
220 ONERR GOTO 300
230 HOME : FOR I = 1 TO NC
240 PN$(I,1) = LEFT$(PN$(I,1),18)
250 PRINT PN$(I,1)" ";: FOR U = 0 TO 18 - LEN(PN$(I,1)): PRINT ".";: NEXT : HTAB (21): PRINT " ";PN$(I,2)
260 IF PEEK(KBD) <127 THEN 290
270 POKE CLKBD,0
280 IF PEEK(KBD) <127 THEN 280
285 IF PEEK(KBD) = 155 THEN POKE CLKBD,0: GOTO 120
290 POKE CLKBD,0: NEXT
300 PRINT : GOTO 120
310 FOR I = 1 TO NC
320 REM IF PN$(I,1) < T$ THEN 320 : IF YOU HAVE THE LIST IN ALPHABETICAL ORDER.
330 IF LEFT$(PN$(I,1), LEN(T$)) = T$ THEN 370
340 NEXT
350 PRINT : CALL -198: PRINT T$" ";: INVERSE : PRINT "NOT IN DIRECTORY";: NORMAL : PRINT " (TRY '?')"
360 FOR HLD = 1 TO 1200: NEXT HLD: HOME : GOTO 120
370 PRINT :PH$ = PFX$ +PN$(I,2): GOTO 390
380 PH$ = PFX$ +T$:C = 1
390 PRINT D$"PR#"SLOT
400 PRINT CHR$(17)PH$ CHR$(10)
410 PRINT D$"PR#0"
420 IF PEEK(KBD) >127 THEN POKE CLRKBD,0: POKE MM2,0: FLASH : PRINT : PRINT "** ABORTED * HUNG UP": NORMAL : CALL -198: FOR H = 1 TO 1000: NEXT : HOME : GOTO 120
430 PRINT : PRINT "YOU MAY PICK UP THE PHONE NOW....": CALL -198
440 PRINT
450 FOR H = 1 TO 2500: NEXT H
460 POKE MM2,0
470 POKE CLKBD,O
480 HOME :C = 1: GOTO 120
1000 DATA 6
1010 DATA HAYES MICROCOMPUTER PRODUCTS,1 (404) 449-8791
1020 DATA SMITH; JOE, 465-9181
1030 DATA JANE; MARY, 378-4567
1040 DATA TRAVELER; TRACY, 555-5555
1050 DATA INFORMATION,411
1060 DATA OK FOOD STORE,921-3412
60000 PRINT : PRINT " <<< RETURNNING TO MENU >>>"
60100 PRINT CHR$(4)"RUN HAYES MENU"
63998 REM LAST UPDATED 12/80
63999 REM HAYES MICROCOMPUTER PRODUCTS,INC.

Text found in 007_Hayes_Micromodem_II_For_Apple_II_Computers.dsk/DJ CONVERTER.bas:

5 REM PROGRAM DJ CONVERTER
6 HOME
10 D$ = CHR$(13) + CHR$(4):QU$ = CHR$(34)
15 PRINT "INSERT A COPY OF YOUR DOW JONES": PRINT "PORTFOLIO EVALUATOR DISK OR HIT": PRINT "CONTROL C TO ABORT AND RETURN TO MENU"
16 GET AN$: IF AN$ = CHR$(3) THEN 60000
19 ONERR GOTO 60000
20 HOME : PRINT : INPUT "ENTER SLOT NUMBER MICROMODEM WILL BE IN ";SL
30 PRINT : INPUT "ENTER YOUR LOCAL DOW JONES ACCESS NUMBER";NM$
40 PRINT D$"OPEN MODIFYDJ"D$"WRITE MODIFYDJ"
50 PRINT "UNLOCK FETCH"
60 PRINT "RENAME FETCH,OLD FETCH"
70 PRINT "LOCK OLD FETCH"
80 PRINT "UNLOCK LOGIN"
90 PRINT "RENAME LOGIN,OLD LOGIN"
100 PRINT "LOCK OLD LOGIN"
110 PRINT "LOAD OLD FETCH"
120 PRINT "6590POKEDA,19:CALL"49154 +256 *SL":REMDC3"
130 PRINT "6910WAITST,2:POKE DA,17:CALL"49154 +256 *SL":REMDC1"
140 PRINT "7120IFIN=1THENWAITST,2:POKEDA,19:CALL"49154 +256 *SL":RUN"
150 PRINT "7145D$=CHR$(4):Z$=CHR$(26)"
160 PRINT "7150?:?D$"QU$"PR#"SL;QU$
170 PRINT "7155?Z$"
180 PRINT "7156?D$"QU$"PR#0"QU$
190 PRINT "7160?:HTAB9:?"QU$"PRESS ANY KEY..."QU$";:GETA$"
200 PRINT "7200IF5*INT(S/5)<>STHENWAITST,2:POKEDA,17:CALL"49154 +256 *SL":GOTO7360"
210 PRINT "7255IFI=0THENI$=I$+SY$(J):NEXTI"
220 PRINT "7300WAITST,2:POKEDA,17:CALL"49154 +256 *SL":REMDC1"
230 PRINT "7380POKEDA,19:CALL"49154 +256 *SL":REMDC3"
240 PRINT "7900ST="49286 +16 *SL":REMADDR OF ACIA STATUS"
250 PRINT "7910DA=1912:REMADDR OF CHAR"
260 PRINT "7970FORI=1TOLEN(I$):WAITST,2:POKEDA,ASC(MID$(I$,I,1)):CALL"49154 +256 *SL":NEXTI"
270 PRINT "SAVE FETCH"
280 PRINT "LOAD OLD LOGIN"
290 PRINT "5025D$=CHR$(4):Q$=CHR$(17):Z$=CHR$(26)"
300 PRINT "5140?CHR$(7):HOME:?:?:HTAB12:FLASH"
310 PRINT "5141?"QU$"INCORRECT PASSWORD"QU$": NORMAL"
320 PRINT "5142IFLGIN=-1THEN?D$"QU$"PR#"SL;QU$":?Z$"
330 PRINT "5143?D$"QU$"PR#0"QU$
340 PRINT "5170TRYNO=0"
350 PRINT "5180NUMBER$="QU$NM$QU$
360 PRINT "5191?"
370 PRINT "5192IFLEN(A$)THENIFASC(A$)=27THEN5050"
380 PRINT "5193TRYNO=TRYNO+1:IFTRYNO<4THEN5197"
390 PRINT "5194HOME:VTAB8:HTAB3:?"QU$"INVALID TELEPHONE NUMBER"QU$
400 PRINT "5195FORPAUSE=1TO2000:NEXTPAUSE:NORMAL"
410 PRINT "5196?D$"QU$"PR#"SL;QU$":?Z$:GOTO6000"
420 PRINT "5197?D$"QU$"PR#"SL;QU$
430 PRINT "5198?Q$NUMBER$"
440 PRINT "5199?D$"QU$"PR#0"QU$
450 PRINT "5201IFPEEK("1656 +SL")>127THEN5210"
460 PRINT "5202?D$"QU$"PR#"SL;QU$":?Z$"
470 PRINT "5203?D$"QU$"PR#0"QU$
480 PRINT "5204?"QU$"TRY AGAIN"QU$
490 PRINT "5205FORPAUSE=1TO1000:NEXTPAUSE"
500 PRINT "5206GOTO5193"
510 PRINT "5640HTAB4:?"QU$"PRESS ANY KEY..."QU$";:GETA$"
520 PRINT "5644?"
530 PRINT "5645?D$"QU$"PR#"SL;QU$
540 PRINT "5646?Z$:?D$"QU$"PR#0"QU$
542 PRINT "5710ST="49286 +16 *SL":REMADDR OF ACIA STATUS"
544 PRINT "5720DA=1912:REMADDR OF CHAR"
546 PRINT "5780FORI=1TOLEN(I$):WAITST,2:POKEDA,ASC(MID$(I$,I,1)):CALL"49154 +256 *SL":NEXTI"
550 PRINT "SAVE LOGIN"
560 IF SL = 2 THEN 650
570 PRINT "UNLOCK COM22.OBJ"
580 PRINT "RENAME COM22.OBJ,OLD COM22.OBJ"
590 PRINT "LOCK OLD COM22.OBJ"
600 PRINT "BLOAD OLD COM22.OBJ"
610 PRINT "POKE 835,182"
620 PRINT "POKE 844,183"
630 PRINT "BSAVE COM22.OBJ,A$300,L$B1"
640 PRINT "LOCK COM22.OBJ"
645 PRINT "NOMON I,O,C"
650 PRINT "CALL-198:CALL-198:CALL-198"
660 PRINT "?"QU$" ALL DONE!"QU$
670 PRINT "DELETE MODIFYDJ"
680 PRINT D$"CLOSE"
690 PRINT D$"MON I"
700 PRINT D$"EXEC MODIFYDJ"
800 END
60000 PRINT : PRINT " <<< RETURNNING TO MENU >>>"
60010 PRINT CHR$(4)"RUN HAYES MENU"
63998 REM LAST UPDATED 12/80,
63999 REM HAYES MICROCOMPUTER PRODUCTS,INC.

Text found in 007_Hayes_Micromodem_II_For_Apple_II_Computers.dsk/DUMBO.int:

1 CALL -936
10 A$="X":AD=2053
20 POKE AD,154:Z$=A$:REM CNTRL-Z
30 FSW=21
40 X=0
50 SLOT=3
60 CR1=-16250+16*SLOT
70 DTA=CR1+1
80 CHAR=1912
90 SEND=-16382+256*SLOT
100 POKE AD,132:D$=A$:REM CNTRL-D
110 POKE AD,145:Q$=A$:REM CNTRL-Q
115 POKE AD,223:CU$=A$:REM CURSOR
116 POKE AD,136:H$=A$:REM CNTRL-H
120 PRINT D$;"IN#";SLOT:PRINT :PRINT D$;"IN#0"
130 KBD=-16384
140 KBRL=KBD+16
150 POKE 768,160: POKE 769,35: POKE 770,76: POKE 771,228: POKE 772,251
160 DIM PH$(25),AN$(5)
170 PRINT "DUMB TERMINAL PROGRAM"
180 PRINT :INPUT "H)ALF OR F)ULL DUPLEX? ",A$
190 F=0:IF A$="F" THEN F=1
200 IF F=0 AND A$#"H" THEN 180
210 INPUT "PARITY E)VEN, O)DD OR N)ONE? ",P$:FSW=21:IF P$="E" THEN FSW=9:IF P$="O" THEN FSW=13:IF P$="N" THEN 220:IF P$#"E" AND P$#"O" AND P$#"N" THEN 210
220 INPUT "BAUD 1)10 OR 3)00 ? ",BAUD
230 IF BAUD=3 THEN 260
240 IF BAUD#1 THEN 220
250 POKE 1656+SLOT, PEEK (1656+SLOT)/2*2
260 INPUT "PHONE NUMBER? ",PH$
270 PRINT D$;"PR#";SLOT:PRINT Q$;PH$
280 PRINT D$;"PR#0"
290 POKE 2040+SLOT,FSW
300 X= PEEK (CR1)
310 IF X>3 THEN 490
320 IF X MOD 2 THEN 440
325 PRINT CU$;H$;:CALL -868
330 X= PEEK (KBD)
340 IF X<128 THEN 300
350 POKE KBRL,0
360 POKE CHAR,X
370 CALL SEND
380 IF F THEN 300
390 IF X=138 THEN 300
400 IF X=128 THEN 300
410 POKE AD,X
420 PRINT A$;
430 GOTO 300
440 X= PEEK (DTA)
450 IF X<128 THEN X=X+128
460 IF X#135 THEN 390
470 CALL 768
480 GOTO 300
490 IF X<8 THEN 530
500 X= PEEK (DTA)
510 POKE 50,63:CALL 768:PRINT " ";: POKE 50,255
520 GOTO 300
530 PRINT :PRINT D$;"PR#";SLOT
540 PRINT Z$
550 PRINT D$;"PR#0"
560 PRINT "*** LOST CARRIER ***":CALL -198
570 PRINT :PRINT :PRINT :PRINT
580 PRINT "RETURN TO MENU? Y";H$;
585 INPUT "",AN$
590 IF AN$="N" THEN 170
600 PRINT " <<< RETURNNING TO MENU >>>"
610 PRINT D$;"RUN HAYES MENU"
32766 REM LAST UPDATED 11/80
32767 REM HAYES MICROCOMPUTER PRODUCTS, INC.

Text found in 007_Hayes_Micromodem_II_For_Apple_II_Computers.dsk/HAYES MENU.bas:

10 TEXT : HOME : PRINT
20 A1$ = "MICROMODEM II PROGRAMS":A2$ = "FROM":A3$ = "HAYES MICROCOMPUTER PRODUCTS, INC."
30 PRINT TAB( INT((40 - LEN(A1$))/2))A1$
40 PRINT TAB( INT((40 - LEN(A2$))/2))A2$
50 PRINT TAB( INT((40 - LEN(A3$))/2));: INVERSE : PRINT A3$: NORMAL
60 FOR I = 1 TO 40: PRINT "-";: NEXT
70 POKE 34,5
80 READ MAX
90 DIM PGM$(MAX)
100 B$ = CHR$(7):D$ = CHR$(4):H$ = CHR$(8)
110 FOR I = 1 TO MAX: READ PGM$(I): NEXT
120 FOR I = 65 TO 64 +MAX
130 S = I -64
150 PRINT CHR$(I)" : "PGM$(S)
160 NEXT : PRINT
170 PRINT "ENTER SELECTION: ";: CALL -868
180 GET AN$:C = ASC(AN$)
190 IF C <65 OR C >64 +MAX THEN PRINT B$;: GOTO 180
200 PRINT :C = C -64
210 VTAB C +5: INVERSE : PRINT AN$;: NORMAL : PRINT " : ";: INVERSE : PRINT PGM$(C): NORMAL : VTAB 20
220 PRINT "SELECTION CORRECT? Y"H$;
230 GET BN$: IF BN$ < >"Y" AND BN$ < >"N" AND BN$ < > CHR$(13) THEN PRINT B$;: GOTO 230
240 PRINT BN$: IF BN$ < >"N" THEN 260
250 VTAB C +5: PRINT AN$" : "PGM$(C): VTAB 20: GOTO 170
260 VTAB 20: PRINT " <<< RUNNING PROGRAM >>>"
270 PRINT D$"RUN "PGM$(C)
999 TEXT
1000 DATA 13
1010 DATA SELFTEST II
1020 DATA STORE & FORWARD
1030 DATA PICKUP
1040 DATA AUTO DIAL
1050 DATA DUMBO
1060 DATA TRANSFER
1070 DATA BASIC EXTRACTOR
1080 DATA ALARM
1090 DATA DIAL A HUMAN
1100 DATA ANSWER ON NTH RING MODIFIED
1110 DATA SOURCEON
1120 DATA DJ CONVERTER
1130 DATA MICROMODEM FLAGS

Text found in 007_Hayes_Micromodem_II_For_Apple_II_Computers.dsk/MICROMODEM FLAGS.bas:

0 REM SERIAL #12-010781-0845A
1 REM MICROMODEM FLAGS BY ED MAGNIN -ALL RIGHTS RESERVED-
2 REM COMPLIMENTARY COPY REPRINTED BY PERMISSION OF ED MAGNIN *** NOT FOR SALE ***
3 REM DISTRIBUTED BY: THE TELEPHONE SOFT- WARE CONNECTION P.O. BOX 6548 TORRANCE, CA 90504 (213) 329-3715 MODEM
4 REM 8/27/80
5 ONERR GOTO 900
10 MF$ = " MICROMODEM FLAGS ":EM$ = " BY ED MAGNIN ":TS$ = "TELEPHONE SOFTWARE CONNECTION":PH$ = "(213) 329-3715 24-HOUR MODEM"
20 HD$ = "HALF DUPLEX":FH$ = "FULL OR " +HD$:LF$ = "LINE FEEDS":TM$ = "TERMINAL PROGRAM":TP$ = "TRANSPARENCY":KB$ = "KEYBOARD ENABLE":FH = 128:LF = 16:TM = 8:TP = 4:KB = 2
30 TEXT : HOME : FOR J = 1024 TO 1104 STEP 40: FOR K = 0 TO 7: POKE J +K *128,32: NEXT K: NEXT J: POKE 32,1: POKE 33,39
40 VTAB 24: HTAB 1: INVERSE : PRINT SPC( 18): PRINT : PRINT MF$: PRINT EM$: PRINT SPC( 18): PRINT
50 FOR J = 1 TO 19: FOR K = 1 TO 100: NEXT K: PRINT : NEXT J: POKE 32,2: POKE 33,38: POKE 34,5
60 NORMAL : VTAB 10: PRINT SPC( 2)"COURTESY OF:": PRINT : PRINT : PRINT SPC( 4)TS$: PRINT SPC( 4)PH$
70 PRINT : PRINT : PRINT SPC( 2)"WHERE FULLY DOCUMENTED AND TESTED": PRINT SPC( 2)"SOFTWARE FOR THE APPLE ]" CHR$(219)" COMPUTER": PRINT SPC( 2)"IS AS CLOSE AS YOUR MODEM.": GOSUB 1000
80 VTAB 14: INPUT "DO YOU WANT AN EXPANATION? ";I$: IF LEFT$(I$,1) = "N" THEN 315
100 REM EXPLANATION
110 VTAB 12: PRINT "IF YOU PLAN ON WRITING ANY PROGRAMS": PRINT : PRINT "FOR THE HAYES MICROMODEM ,": PRINT : PRINT "YOU SHOULD BECOMER FAMILIAR WITH ITS": PRINT : PRINT "FLAGS LOCATION.": GOSUB 1000
120 VTAB 10: PRINT "THE FLAGS ARE LOCATED AT 1912 PLUS THE": PRINT "SLOT YOUR MICROMODEM IS IN."
130 VTAB 16: INPUT "WHAT SLOT IS YOURS IN? ";SL$:SL = VAL(SL$): IF SL <1 OR SL >7 THEN PRINT : GOTO 130
140 PRINT : PRINT "THEN YOUR FLAGS ARE LOCATED AT "1912 +SL".": GOSUB 1000
150 VTAB 8: PRINT "EVEN THOUGH YOU KNOW YOUR FLAGS ARE": PRINT : PRINT "AT LOCATION "1912 +SL", IF YOU ARE WRITING": PRINT : PRINT "A PROGRAM, IT IS BETTER TO SET THE": PRINT : PRINT "VARIALBLE 'SLOT' EQUAL TO YOUR SLOT.": PRINT
160 PRINT : PRINT : PRINT "THEN YOU ONLY HAVE TO CHANGE ONE LINE": PRINT : PRINT "IF YOU DECIDE TO MOVE YOUR MODEM TO": PRINT : PRINT "ANOTHER SLOT.": GOSUB 1000
200 REM FUNCTIONS
210 VTAB 9: PRINT "THE FLAGS CONTROL THE FOLLOWING": PRINT : PRINT "FUNCTIONS:": PRINT : PRINT : PRINT SPC( 5)FH$: PRINT : PRINT SPC( 5)LF$: PRINT : PRINT SPC( 5)TM$: PRINT : PRINT SPC( 5)TP$: PRINT : PRINT SPC( 5)KB$: GOSUB 1000
220 VTAB 8: PRINT TAB( 22 - LEN(FH$)/2)FH$: PRINT : PRINT : PRINT HD$: PRINT : PRINT SPC( 3)"EACH CHARACTER IS DISPLAYED ON": PRINT SPC( 3)"YOUR SCREEN PRIOR TO BEING": PRINT SPC( 3)"TRANSMITTED.": PRINT : PRINT
230 PRINT LEFT$(FH$,5) + RIGHT$(FH$,6): PRINT : PRINT SPC( 3)"WAITS FOR EACH CHARACTER TO ECHO": PRINT SPC( 3)"PRIOR TO BEING DISPLAYED.": GOSUB 1000
240 VTAB 10: PRINT TAB( 22 - LEN(LF$)/2)LF$: PRINT : PRINT : PRINT : PRINT SPC( 3)"IF SELECTED, AUTOMATICALLY ADDS A": PRINT : PRINT SPC( 3)"LINE FEED FOLLOWING EACH CARRIAGE": PRINT : PRINT SPC( 3)"RETURN.": GOSUB 1000
250 VTAB 10: PRINT TAB( 22 - LEN(TM$)/2)TM$: PRINT : PRINT : PRINT : PRINT SPC( 3)"IF SELECTED, PUTS MICROMODEM INTO": PRINT : PRINT SPC( 3)"ITS TERMINAL PROGRAM.": GOSUB 1000
260 VTAB 10: PRINT TAB( 22 - LEN(TP$)/2)TP$: PRINT : PRINT : PRINT : PRINT SPC( 3)"IF SELECTED, IGNORES INCOMING": PRINT : PRINT SPC( 3)"MODEM CONTROL CHARACTERS.": GOSUB 1000
270 VTAB 10: PRINT TAB( 22 - LEN(KB$)/2)KB$: PRINT : PRINT : PRINT : PRINT SPC( 3)"IF NOT SELECTED, LOCKS OUT YOUR": PRINT : PRINT SPC( 3)"KEYBOARD.": GOSUB 1000
280 VTAB 8: PRINT "SIMPLY ADD UP THE VALUES OF THE": PRINT "DESIRED FUNCTIONS AND POKE THE": PRINT "TOTAL INTO THE FLAGS LOCATION:": PRINT : PRINT
300 REM CALCULATION
305 PRINT SPC( 5)"FULL" + RIGHT$(HD$,7) TAB( 30)FH: PRINT : PRINT SPC( 5)LF$ TAB( 31)LF: PRINT : PRINT SPC( 5)TM$ TAB( 32)TM: PRINT : PRINT SPC( 5)TP$ TAB( 32)TP: PRINT : PRINT SPC( 5)KB$ TAB( 32)KB: GOSUB 1000
310 VTAB 15: PRINT "NOW FOR SOME SAMPLE CALCULATIONS...": GOSUB 1000
315 HOME : VTAB 8: PRINT "WHICH OPTIONS:"
320 VTAB 10: PRINT SPC( 3)FH$ TAB( 25);: INPUT "F OR H ? ";I$: IF I$ < >"F" AND I$ < >"H" THEN 320
325 X = FH *(I$ = "F"):T = X: VTAB 10: HTAB 25: CALL -868: PRINT TAB( 30) SPC( 2 * NOT X)X
330 VTAB 12: PRINT SPC( 3)LF$ TAB( 25);: INPUT "Y OR N ? ";I$: IF I$ < >"Y" AND I$ < >"N" THEN 330
335 X = LF *(I$ = "Y"):T = T +X: VTAB 12: HTAB 25: CALL -868: PRINT TAB( 31) SPC( NOT X)X
340 VTAB 14: PRINT SPC( 3)TM$ TAB( 25);: INPUT "Y OR N ? ";I$: IF I$ < >"Y" AND I$ < >"N" THEN 340
345 X = TM *(I$ = "Y"):T = T +X: VTAB 14: HTAB 25: CALL -868: PRINT TAB( 32)X
350 VTAB 16: PRINT SPC( 3)TP$ TAB( 25);: INPUT "Y OR N ? ";I$: IF I$ < >"Y" AND I$ < >"N" THEN 350
355 X = TP *(I$ = "Y"):T = T +X: VTAB 16: HTAB 25: CALL -868: PRINT TAB( 32)X
360 VTAB 18: PRINT SPC( 3)KB$ TAB( 25);: INPUT "Y OR N ? ";I$: IF I$ < >"Y" AND I$ < >"N" THEN 360
365 X = KB *(I$ = "Y"):T = T +X: VTAB 18: HTAB 25: CALL -868: PRINT TAB( 28)"+" TAB( 32)X: PRINT TAB( 27)"-------": PRINT TAB( 30 +(T <100) +(T <10))T
375 VTAB 22: PRINT "POKE 1912 + SLOT,"T
380 VTAB 24: HTAB 23: INVERSE : PRINT " TRY ANOTHER? ";: GET I$: NORMAL : IF I$ < >"Y" AND I$ < >"N" THEN 380
385 IF I$ = "Y" THEN 315
900 REM EXIT
910 PRINT : TEXT : NORMAL : VTAB 5: CALL -958
920 PRINT : PRINT " <<< RETURNNING TO MENU >>>"
930 PRINT CHR$(4)"RUN HAYES MENU"
1000 REM READY?
1010 VTAB 24: HTAB 23: INVERSE : INPUT " PRESS 'RETURN'";I$: NORMAL : HOME : RETURN

Text found in 007_Hayes_Micromodem_II_For_Apple_II_Computers.dsk/PICKUP.bas:

1 REM PROGRAM TO PICK UP PHONE
2 REM IN ANSWER MODE
10 HOME
20 PRINT : PRINT "THIS PROGRAM WILL TURN ON THE"
30 PRINT "MICROCOUPLER AND SEND THE ANSWER CARRIER"
40 PRINT "CONTINUE? N" CHR$(8);
50 GET AN$: PRINT AN$: IF AN$ < >"Y" THEN 60000
90 ONERR GOTO 9000
100 MSLOT = 3
200 D$ = CHR$(4)
300 PRINT D$;"PR#";MSLOT
400 PRINT
500 POKE 1656 +MSLOT,128 +8 +2 +1
600 POKE 2040 +MSLOT,21
610 POKE -16250 +16 *MSLOT,21
650 PRINT
700 IF PEEK( -16250 +16 *MSLOT) = 2 THEN 1000
800 X = PEEK( -16249 +16 *MSLOT)
900 GOTO 700
1000 PRINT D$;"PR#0"
1100 PRINT D$;"IN#";MSLOT
1200 PRINT "CONNECTION ESTABLISHED"
1300 POKE 1912 +MSLOT,128 +8 +2
1400 INPUT I$
1500 END
9000 PRINT CHR$(26): PRINT D$;"PR#0"
60000 VTAB 12
60010 PRINT " <<< RETURNING TO MENU >>>"
60020 PRINT CHR$(4)"RUN HAYES MENU"
63998 REM LAST UPDATED 11/80
63999 REM HAYES MICROCOMPUTER PRODUCTS,INC.

Text found in 007_Hayes_Micromodem_II_For_Apple_II_Computers.dsk/SELFTEST II.bas:

5 REM SELFTEST PROGRAM IN APPLESOFT
10 CK = 122440: REM ROM/EPROM (REV K) CHECKSUM
20 HOME : ONERR GOTO 33400
30 PRINT " SELF-TEST PROGRAM FOR THE"
40 PRINT " HAYES MICROMODEM II"
60 PRINT : PRINT
100 INPUT "WHICH SLOT IS THE MICROMODEM II IN? ";SLOT
110 PRINT : PRINT "UNPLUG THE MICROMODEM II"
112 PRINT "FROM THE MICROCOUPLER": PRINT
115 INPUT "PRESS RETURN WHEN THIS IS DONE...";I$
200 DTA = -16249 +16 *SLOT
300 ACIA = DTA -1:MDEM = DTA -2:CHAR = 1912
400 T = 0:M = 0:B = 0: HOME
600 REM SETUP MODEM FOR TEST
700 GOSUB 20000
800 REM PERFORM TEST
900 GOSUB 10000
1000 T = T +E
1100 IF M OR B = 1 THEN 700
1200 POKE MDEM,8: PRINT : PRINT
1300 PRINT "HARDWARE TEST COMPLETE": PRINT
1400 PRINT T;" ERRORS DETECTED"
1500 GOTO 30000: REM NOW TEST FIRMWARE
10000 PRINT "COMMENCING TEST"
10200 E = 0
10300 POKE ACIA,3
10400 POKE ACIA,21
10450 S = 0:R = 0
10500 REM
10550 L = PEEK(ACIA)
10551 LMOD = L -( INT(L/2) *2)
10552 IF LMOD = 1 THEN 11100
10600 IF PEEK(ACIA) <2 THEN 10500
10620 IF (S -R) <4 THEN 10700
10630 PRINT "NO DATA RECEIVED" CHR$(7)
10650 E = E +1: RETURN
10700 IF S >127 THEN 10500
10800 POKE CHAR,S
10850 CALL -16382 +256 *SLOT
10900 S = S +1
11000 GOTO 10500
11100 X = PEEK(DTA)
11200 IF X = R THEN 11400
11300 E = E +1: VTAB CV: PRINT E;" ERRORS" CHR$(7)
11400 R = R +1
11500 IF R <128 THEN 10500
11600 PRINT "TEST COMPLETED"
11800 RETURN
20000 POKE MDEM,8
20050 POKE ACIA,3
20100 IF PEEK(ACIA) <4 THEN 20100
20150 PRINT : PRINT : PRINT "TESTING ";
20210 MODE$ = "ORIGINATE"
20220 IF M = 1 THEN 20240
20230 MODE$ = "ANSWER"
20240 BAUD = 300
20250 IF B = 1 THEN 20270
20260 BAUD = 110
20270 PRINT BAUD" BAUD "MODE$" MODE"
20280 CV = PEEK(37)
20300 POKE MDEM,154 +4 *M +B
20400 M = M < >1
20500 IF M < >0 THEN 20700
20600 B = B < >1
20700 DLY = 0
20710 DLY = DLY +1
20720 IF PEEK(ACIA) <4 THEN RETURN
20730 IF DLY <500 THEN 20710
20740 PRINT "NO CARRIER DETECT" CHR$(7)
20750 E = E +1
20800 RETURN
30000 REM FIRMWARE TEST ROUTINE
30050 PRINT : PRINT
30100 PRINT "STARTING FIRMWARE TEST"
30200 PRINT "IT WILL BE DONE AT # 1024": PRINT
30250 CV = PEEK(37)
30300 RB = 778: REM BYTE READ FROM FIRMWARE
30400 POKE 768,173: REM LDA
30500 POKE 769,0: REM 00
30600 POKE 770,192 +SLOT
30700 POKE 771,173: REM LDA
30800 POKE 774,141: REM STA
30900 POKE 775,10: REM 0A
31000 POKE 776,3: REM 03
31100 POKE 777,96: REM RTS
32000 A = PEEK( -12289): REM TURN OFF OTHER ROMS
32100 X = 0: REM CLEAR CHECKSUM
32200 FOR H = 200 TO 203
32300 FOR L = 0 TO 255
32400 POKE 772,L: POKE 773,H
32500 CALL 768:X = X + PEEK(RB)
32550 Z = Z +1: VTAB CV: PRINT Z
32600 NEXT : REM L
32700 NEXT : REM H
32800 PRINT
32900 IF X = CK THEN PRINT "FIRMWARE IS OK": GOTO 33100
33000 FLASH : PRINT "FIRMWARE IS DEFECTIVE": NORMAL : CALL -198: CALL -198: CALL -198
33100 FOR H = 1 TO 500
33200 IF PEEK( -16384) >127 THEN 33400
33300 NEXT
33400 PRINT : PRINT : VTAB 24: PRINT " <<< RETURNING TO MENU >>>"
33500 PRINT CHR$(4)"RUN HAYES MENU"
63998 REM OUR THANKS TO ROBERT J. DENISON
63999 REM FOR APPLESOFT CONVERSION.

Text found in 007_Hayes_Micromodem_II_For_Apple_II_Computers.dsk/SOURCEON.bas:

1 TEXT : HOME
2 PRINT : PRINT "CHECK THESE LINE NUMBERS IN THE PROGRAM:"
3 VTAB 3: LIST 20: VTAB 4: LIST 80: VTAB 7: LIST 120: VTAB 10: LIST 130
6 PRINT : PRINT "WHEN THEY ARE CHANGED THEN:": PRINT
7 PRINT "DEL 1,10 TO ERASE THESE LINES,"
8 PRINT "SAVE SOURCEON FOR A WORKING COPY"
9 PRINT : PRINT "RETURN TO MENU? Y" CHR$(8);
10 GET AN$: PRINT AN$: IF AN$ < >"N" THEN PRINT : PRINT " <<< RETURNNING TO MENU >>>": PRINT CHR$(4)"RUN HAYES MENU"
20 SLOT = 3: REM MM2 SLOT #
25 D$ = CHR$(4)
29 REM CC$ IS THE CHARACTER TO LOOK FOR AND CC IS A PLACE COUNTER
30 CC$ = "=":CC = 0
40 P1 = ( -16250 +16 *SLOT)
50 KBD = -16384:CLRKBD = -16368:ST = -16250 +16 *SLOT:DTA = -16249 +16 *SLOT
60 DTA = -16249 +16 *SLOT
80 NN$ = "TELEPHONE ACCESS #":PFX$ = "": REM PFX IS A PREFIX IF NEEDED.
90 WT = 3000: REM FOR-NEXT WAIT
95 HOME
100 NORMAL : PRINT : INPUT "TRIES IF BUSY? ";TRYS%
110 IF TRYS% <0 THEN HOME : END
120 ID$ = "YOUR ID #": REM PUT THE PASSWORD ON THE END USING 'CHR$(X)' FUNCTION
121 REM ID$="IDENT"+CHR$(4)+CHR$(9)+CHR$(11)+...
130 TRM$ = "YOUR TELENET SIGNON"
140 FOR RD = 0 TO TRYS%
150 IF PEEK(KBD) >127 THEN POKE CLRKBD,0: PRINT : INVERSE : PRINT "** DIALING ABORTED **" + CHR$(7): GOTO 100
160 PRINT D$"PR#"SLOT
170 PRINT CHR$(17)PFX$NN$
180 IF PEEK(1656 +SLOT) >127 THEN 210
190 PRINT D$"PR#0": PRINT : INVERSE : PRINT "#"RD" *** NO CARRIER ***": NORMAL
200 NEXT RD: GOTO 290
210 FOR H = 1 TO 2000: NEXT H
220 REM ---TWO (2) 'RETURNS'--->
230 PRINT CHR$(13);: FOR H = 1 TO 500: NEXT H: PRINT CHR$(13);
240 PRINT D$"PR#0": PRINT D$"IN#"SLOT
250 FOR XX = 0 TO WT
255 REM IS THERE A CHARACTER TO RECEIVE??
260 IF PEEK(P1) = 3 THEN 300
270 NEXT XX
280 IF T0 THEN 290: PRINT : INVERSE : PRINT "*** TIME OUT ***":T0 = 1: NORMAL : GOTO 240
290 HOME : PRINT D$"IN#0": PRINT D$"PR#"SLOT: PRINT CHR$(26): PRINT D$"PR#0": VTAB 12: PRINT "MAYBE ANOTHER TIME": END
299 REM IS IT THE CHARATER WE ARE LOOKING FOR???
300 IF CHR$( PEEK(DTA)) < >CC$ THEN PRINT CHR$( PEEK(DTA));: GOTO 250
310 PRINT CHR$( PEEK(DTA));:T0 = 0
320 PRINT : PRINT D$"IN#0": PRINT D$"PR#"SLOT
330 ON CC GOTO 360,370,390
340 PRINT CHR$(13);
350 CC$ = "@":CC = 1: GOTO 240
360 PRINT TRM$:CC$ = ">":CC = 2: GOTO 240
370 PRINT ID$
380 WT = 10000:CC = 3:CC$ = ")": GOTO 240
389 REM THIS PUTS YOU IN TERMINAL MODE, BUT YOU CAN DO OTHER THINGS BESIDES THAT....
390 PRINT : PRINT D$"PR#0": PRINT D$"IN#"SLOT
400 POKE 1912 +SLOT,138: GET Z$
410 HOME : END
63998 REM LAST UPDATED 12/80
63999 REM HAYES MICROCOMPUTER PRODUCTS,INC.

Text found in 007_Hayes_Micromodem_II_For_Apple_II_Computers.dsk/STORE & FORWARD.bas:

1 REM STORE & FORWARD PROGRAM
2 REM RECEIVES A MESSAGE AND
3 REM FORWARDS IT TO ANOTHER
4 REM COMPUTER.
10 DIM LINE$(100)
50 TEXT : HOME
90 I = 0:J = 0:K = 0
100 REM SLOT MUST = SLOT MICROMODEM II IS IN
400 SLOT = 3
900 REM THIS SETS UP THE PASSWORD
1000 PASS$ = "DEMO"
1100 Z$ = CHR$(26):Q$ = CHR$(17):D$ = CHR$(4)
1200 ONERR GOTO 60000
1300 PRINT D$;"PR#";SLOT: PRINT Z$
1350 POKE 1912 +SLOT,22
1400 PRINT D$;"IN#";SLOT: INPUT "WAITING FOR THE PHONE TO RING";I$
1500 IF PEEK(1656 +SLOT) <128 THEN 1300
1600 PRINT "HELLO, THIS IS A STORE AND FORWARD"
1700 PRINT "PROGRAM RUNNING ON AN APPLE II"
1800 I = 0
1900 INPUT "PASSWORD ";I$
2000 IF I$ = PASS$ THEN 2500
2100 PRINT "INCORRECT PASSWORD"
2200 I = I +1
2300 IF I >2 THEN 1300
2400 GOTO 1900
2500 PRINT "CORRECT PASSWORD"
2600 PRINT "THIS PROGRAM WILL FORWARD A SHORT"
2700 PRINT "MESSAGE TO ANOTHER COMPUTER OR TERMINAL"
2800 PRINT
2900 INPUT "PLEASE ENTER ITS PHONE NUMBER ";NUMBER$
3000 PRINT
3100 PRINT "YOU MAY ENTER A MESSAGE:"
3200 PRINT "TYPE 'END' TO END MESSAGE"
3250 L = 0
3300 PRINT
3350 L = L +1
3400 IF L <9 THEN PRINT " ";
3500 PRINT L;
3600 INPUT ")";LINE$(L)
3700 IF LINE$(L) = "END" THEN 3900
3800 GOTO 3350
3900 L = L -1: PRINT
4000 PRINT "I CAN WAIT A FEW MINUTES BEFORE"
4100 PRINT "I FORWARD THE MESSAGE."
4200 INPUT "HOW MANY MINUTES? ";T
4300 PRINT
4400 PRINT "THANK YOU"
4500 PRINT "IN ";T;" MINUTES, I WILL FORWARD THE"
4600 PRINT "FOLLOWING MESSAGE TO PHONE NUMBER ";NUMBER$
4700 PRINT : FOR I = 1 TO L
4800 PRINT LINE$(I)
4900 NEXT
5000 PRINT
5300 PRINT
5400 INPUT "IS THAT OK?";I$
5500 IF LEFT$(I$,1) < >"Y" THEN 2600
5600 PRINT "GOOD BYE"
5650 POKE 1912 +SLOT,18
5700 PRINT Z$
5750 FOR I = 1 TO 700: NEXT I
5800 REM NOW WAIT T MINUTES
5850 IF T <1 THEN 6200
5880 PRINT "WAITING "T" MINUTES": PRINT "NOW ON MINUTE ";
5900 FOR I = 1 TO T
5950 PRINT I" ";
6000 GOSUB 30000
6100 NEXT : PRINT
6200 I = 0
6300 PRINT Q$;NUMBER$
6400 IF PEEK(1656 +SLOT) >127 THEN 7100
6500 I = I +1
6600 IF I >3 THEN 1300
6650 PRINT : PRINT "NO CONNECTION....WAITING 5 MINUTES"
6660 PRINT "NOW ON MINUTE ";
6700 FOR L = 1 TO 5
6750 PRINT L" ";
6800 GOSUB 30000
6900 NEXT : PRINT
7000 GOTO 6300
7100 REM FIRST GIVE HIM SOME TIME
7200 REM FOR AN ANSWERBACK MESSAGE
7350 FOR I = 1 TO 2000: NEXT I
7375 PRINT "HELLO, MESSAGE FOLLOWS:"
7400 PRINT
7500 FOR I = 1 TO L
7600 PRINT LINE$(I)
7700 NEXT
7900 PRINT
8000 PRINT Z$
8100 GOTO 1200
29900 REM SUBROUTINE TO DELAY 1 MINUTE
30000 FOR J = 1 TO 45810
30200 NEXT J
30300 RETURN
60000 REM ERROR ROUTINE
60010 PRINT "ERROR #" PEEK(222)" IN LINE " PEEK(218) + PEEK(219) *256
60020 POKE 1912 +SLOT,2: PRINT Z$
60030 PRINT : PRINT D$"PR#0": PRINT D$"IN#0": POKE 216,0
60040 PRINT : PRINT "RETURN TO MENU? Y" CHR$(8);
60050 GET AN$: IF AN$ < >"N" THEN PRINT : PRINT " <<< RETURNING TO MENU >>>": PRINT D$"RUN HAYES MENU"
60060 STOP
63998 REM LAST UPDATED 11/80
63999 REM HAYES MICROCOMPUTER PRODUCTS,INC.

Text found in 007_Hayes_Micromodem_II_For_Apple_II_Computers.dsk/TRANSFER.bas:

1 REM TRANSFER PROGRAM
2 REM TRANSFERS 'TEXT' FILES
3 REM BETWEEN APPLE ]['S WITH
4 REM THE MICROMODEM ][
100 MSLOT = 3
200 D$ = CHR$(4):AK$ = CHR$(6):CR$ = CHR$(13)
225 EF$ = CHR$(3):RE$ = CHR$(18)
250 PRINT D$;"NOMONI,O,C"
300 GOSUB 500: GOTO 3500
400 PRINT D$;"IN#0": RETURN
500 PRINT D$;"PR#0": RETURN
600 PRINT D$;"IN#";MSLOT: RETURN
700 PRINT D$;"PR#";MSLOT: RETURN
900 GOSUB 400: GOSUB 500
1000 INPUT "FILE NAME? ";F$
1100 IF LEN(F$) = 0 THEN 60000
1200 PRINT D$"OPEN "F$
1300 INPUT "S)END OR R)ECEIVE? ";I$
1400 IF LEFT$(I$,1) = "R" THEN 4000
1450 IF LEFT$(I$,1) < >"S" THEN 1100
1500 ONERR GOTO 3000
1550 POKE 1912 +MSLOT,2
1600 GOTO 2300
1800 GOSUB 700: GOSUB 400
1850 PRINT D$;"READ ";F$
1900 I$ = ""
2000 GET A$: IF A$ = CR$ THEN 2200
2100 I$ = I$ +A$: GOTO 2000
2200 PRINT D$;I$
2300 GOSUB 500: GOSUB 600
2400 GET A$: IF A$ < >AK$ THEN 2400
2450 FOR I = 1 TO 15: NEXT I
2500 PRINT : GOTO 1800
3000 X = PEEK(222): POKE 216,0
3100 GOSUB 400: GOSUB 500
3200 IF X < >5 THEN 9000
3300 GOSUB 700: PRINT EF$;EF$: GOSUB 500
3400 PRINT : PRINT "FILE SENT"
3500 GOSUB 600: POKE 1912 +MSLOT,8 +2
3600 INPUT F$
3650 GOSUB 700: PRINT RE$
3700 GOTO 900
4000 PRINT
4025 PRINT D$;"MON O"
4050 X = FRE(0)
4100 GOSUB 500: GOSUB 600
4200 I$ = ""
4250 POKE 1912,134: CALL -16382 +256 *MSLOT
4300 GET A$: IF A$ = CR$ THEN 4600
4400 IF A$ = EF$ THEN 5000
4500 I$ = I$ +A$: GOTO 4300
4600 PRINT : PRINT D$;"WRITE ";F$
4700 PRINT I$
4800 GOTO 4050
5000 PRINT : GOSUB 400
5100 PRINT D$;"CLOSE ";F$
5200 PRINT "FILE RECEIVED"
5300 GOTO 3500
60000 PRINT : PRINT : PRINT "RETURN TO MENU? N" CHR$(8);
60010 GET AN$: PRINT AN$: IF AN$ = "Y" THEN 60030
60020 GOTO 3500
60030 PRINT : PRINT " <<< RETURNNING TO MENU >>>"
60040 PRINT CHR$(4)"RUN HAYES MENU"
63998 REM LAST UPDATED 11/80
63999 REM HAYES MICROCOMPUTER PRODUCTS,INC.